↑  ←  Описание функции

_GUICtrlListView_SetIconSpacing

Устанавливает интервал между иконками, при использовании стиля "large icon"

#include <GuiListView.au3>
_GUICtrlListView_SetIconSpacing($hWnd, $iCX, $iCY)

Параметры

$hWnd Дескриптор или идентификатор элемента
$iCX Интервал в пикселях, устанавливаемый между иконками по оси X
$iCY Интервал в пикселях, устанавливаемый между иконками по оси Y

Возвращаемое значение

Возвращает массив следующего формата:
        [0] - Предыдущее значение CX
        [1] - Предыдущее значение CY

Примечания

Значения $iCX и $iCY определяются относительно верхнего левого угла иконки. Чтобы установить интервал между иконками, который не приводит к перекрыванию иконок друг другом, значения $iCX и/или $iCY должны включать в себя размер иконки и желаемый интервал между иконками. Значения, которые менее ширины иконок приводят к перекрыванию иконок друг другом.

Пример

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>

$Debug_LV = False ; Проверяет ClassName передаваемый в ListView функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hImage, $hListView

    ; Создаёт GUI
    GUICreate("Устанавливает интервал между иконками", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUICtrlSetStyle($hListView, $LVS_ICON)
    GUISetState()

    ; Загружает изображения
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x0000FF, 16, 16))
    _GUICtrlListView_SetImageList($hListView, $hImage, 0)

    ; Добавляет пункты
    _GUICtrlListView_AddItem($hListView, "Пункт 1", 0)
    _GUICtrlListView_AddItem($hListView, "Пункт 2", 1)
    _GUICtrlListView_AddItem($hListView, "Пункт 3", 2)

    ; Изменяет интервал между иконками
    MsgBox(4160, "Информация", "Изменяет интервал между иконками")
    _GUICtrlListView_SetIconSpacing($hListView, 32, 32)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main