↑  ←  Описание функции

_GUICtrlListView_AddItem

Добавляет новый пункт в конец списка ListView

#include <GuiListView.au3>
_GUICtrlListView_AddItem($hWnd, $sText [, $iImage = -1 [, $iParam = 0]])

Параметры

$hWnd Дескриптор или идентификатор элемента
$sText Текст пункта. Если установлено -1, пункт устанавливается с помощью уведомительного сообщения $LVN_GETDISPINFO.
$iImage [необязательный] Индекс иконки в списке изображений, отсчёт от 0
$iParam [необязательный] Данные определяемые приложением (число). Смотрите также _GUICtrlListView_GetItemParam

Возвращаемое значение

Успех:Возвращает индекс пункта
Ошибка:Возвращает -1

Примечания

Вы не можете использовать эту функцию, чтобы вставить подпункт. Используйте _GUICtrlListView_AddSubItem, чтобы вставить подпункт.

См. также

_GUICtrlListView_AddSubItem

Пример

#include <GuiListView.au3>
#include <GuiImageList.au3>
#include <GUIConstantsEx.au3>

; Создание GUI
GUICreate("Добавление пунктов в ListView", 400, 300)
$iListView = GUICtrlCreateListView("", 2, 2, 394, 268)
GUISetState()

; Устанавливает изображения
$hImage = _GUIImageList_Create()
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($iListView, 0xFF0000, 16, 16))
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($iListView, 0x00FF00, 16, 16))
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($iListView, 0x0000FF, 16, 16))
_GUICtrlListView_SetImageList($iListView, $hImage, 1)

; Добавляет колонки
_GUICtrlListView_InsertColumn($iListView, 0, "Колонка 1", 100)
; _GUICtrlListView_InsertColumn($iListView, 1, "Колонка 2", 100)

; Добавляет пункты
$0 = _GUICtrlListView_AddItem($iListView, "Пункт 1", 0, 856)
$1 = _GUICtrlListView_AddItem($iListView, "Пункт 2", 1, 1098)
$2 = _GUICtrlListView_AddItem($iListView, "Пункт 3", 2, 34)

MsgBox(0, 'Индекс и ассоциативный параметр', _
$0 & ' = ' & _GUICtrlListView_GetItemParam($iListView, 0) & @CRLF & _
$1 & ' = ' & _GUICtrlListView_GetItemParam($iListView, 1) & @CRLF & _
$2 & ' = ' & _GUICtrlListView_GetItemParam($iListView, 2))

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE