↑  ←  Описание функции

_GUICtrlListView_SetImageList

Назначает список изображений элементу ListView

#include <GuiListView.au3>
_GUICtrlListView_SetImageList($hWnd, $hHandle [, $iType = 0])

Параметры

$hWnd Дескриптор или идентификатор элемента
$hHandle Дескриптор назначаемого списка изображений
$iType [необязательный] Тип списка изображений:
    0 - Список изображений с большими иконками
    1 - Список изображений с маленькими иконками
    2 - Список изображений с изображениями состояния

Возвращаемое значение

Успех:Возвращает дескриптор предыдущего списка изображений
Ошибка:Возвращает 0

Примечания

Текущий список изображений уничтожается при удалении ListView, если не задан стиль $LVS_SHAREIMAGELISTS. If you use this message to replace one image list with another your application must explicitly destroy all image lists other than the current one.

См. также

_GUICtrlListView_GetImageList

Пример

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>

$Debug_LV = False ; Проверяет ClassName передаваемый в ListView функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hImage, $hListView

    GUICreate("Устанавливает список изображений", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState()

    ; Загружает изображения
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x0000FF, 16, 16))
    _GUICtrlListView_SetImageList($hListView, $hImage, 1)

    ; Добавляет колонки
    _GUICtrlListView_AddColumn($hListView, "Колонка 1", 100)
    _GUICtrlListView_AddColumn($hListView, "Колонка 2", 100)
    _GUICtrlListView_AddColumn($hListView, "Колонка 3", 100)

    ; Добавляет пункты
    _GUICtrlListView_AddItem($hListView, "Пункт 1", 0)
    _GUICtrlListView_AddItem($hListView, "Пункт 2", 1)
    _GUICtrlListView_AddItem($hListView, "Пункт 3", 2)

    ; Получает дескриптор списка изображений
    MsgBox(4160, "Информация", "Дескриптор списка изображений: 0x" & Hex(_GUICtrlListView_GetImageList($hListView, 1)))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main