↑  ←  Описание функции

_GUICtrlListView_CreateSolidBitMap

Создаёт bitmap залитый сплошным цветом

#include <GuiListView.au3>
_GUICtrlListView_CreateSolidBitMap($hWnd, $iColor, $iWidth, $iHeight)

Параметры

$hWnd Дескриптор или идентификатор элемента
$iColor Цвет bitmap, в формате RGB
$iWidth Ширина bitmap
$iHeight Высота bitmap

Возвращаемое значение

Возвращает дескриптор bitmap

Пример

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>

$Debug_LV = False ; Проверяет ClassName передаваемый в ListView функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hImage, $hListView

    GUICreate("ListView - Создаёт сплошной BitMap", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState()

    ; Загружает изображения
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap(GUICtrlGetHandle($hListView), 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap(GUICtrlGetHandle($hListView), 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap(GUICtrlGetHandle($hListView), 0x0000FF, 16, 16))
    _GUICtrlListView_SetImageList($hListView, $hImage, 1)

    ; Добавляет колонки
    _GUICtrlListView_AddColumn($hListView, "Пункты", 140)

    ; Добавляет пункты
    _GUICtrlListView_AddItem($hListView, "Пункт 1", 0)
    _GUICtrlListView_AddItem($hListView, "Пункт 2", 1)
    _GUICtrlListView_AddItem($hListView, "Пункт 3", 2)

    ; Устанавливает отступы пунктов
    _GUICtrlListView_SetItemIndent($hListView, 1, 1)
    _GUICtrlListView_SetItemIndent($hListView, 2, 2)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main