↑  ←  Описание функции

_GUICtrlToolbar_SetRows

Устанавливает количество строк с кнопками

#include <GuiToolBar.au3>
_GUICtrlToolbar_SetRows($hWnd, $iRows [, $fLarger = True])

Параметры

$hWnd Дескриптор элемента
$iRows Количество строк. Минимальное значение равно 1, а максимальное равно общему количеству кнопок.
$fLarger [необязательный] Флаг, указывающий, следует ли создавать больше строк, чем запрошено, когда система не может создать количество строк, заданное параметром $iRows.
    True - система создаст больше строк.
    False - система создаст меньше строк.

Возвращаемое значение

Успех: Возвращает массив следующего формата:
        [0] - X-координата левого верхнего угла прямоугольника
        [1] - Y-координата левого верхнего угла прямоугольника
        [2] - X-координата правого нижнего угла прямоугольника
        [3] - Y-координата правого нижнего угла прямоугольника

Примечания

Поскольку система не разбивает группы кнопок при установке числа строк, в результате количество строк может отличаться от заданного числа.

См. также

_GUICtrlToolbar_GetRows

Пример

#include <GuiToolbar.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

$Debug_TB = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает
Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $hToolbar
    Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp

    ; Создаёт GUI
    $hGUI = GUICreate(StringTrimRight(@ScriptName, 4), 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    $iMemo = GUICtrlCreateEdit("", 36, 2, 362, 296, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 10, 400, 0, "Courier New")
    GUISetState()

    ; Добавляет стандартный системный bitmaps
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; Добавляет кнопки
    _GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; Создаёт вертикальный Toolbar
    _GUICtrlToolbar_SetStyle($hToolbar, BitOR($CCS_LEFT, $TBSTYLE_FLAT))
    _GUICtrlToolbar_SetRows($hToolbar, 4)

    ; Показывает количество строк
    MemoWrite("Количество строк:" & _GUICtrlToolbar_GetRows($hToolbar))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite