↑  ←  Описание функции

_GUICtrlToolbar_SetStyle

Устанавливает стиль Toolbar

#include <GuiToolBar.au3>
_GUICtrlToolbar_SetStyle($hWnd, $iStyle)

Параметры

$hWnd Дескриптор элемента
$iStyle Стили Toolbar. Это может быть комбинацией следующих значений:
    $TBSTYLE_TOOLTIPS - Создаёт элемент подсказки ToolTip
    $TBSTYLE_WRAPABLE - Панель инструментов автоматически переносится на новую строку, если не умещается в окне.
    $TBSTYLE_ALTDRAG - Позволяет пользователю изменять положение кнопки Toolbar перетаскивая их.
    $TBSTYLE_FLAT - Создаёт плоскую панель инструментов
    $TBSTYLE_LIST - Создаёт плоскую панель инструментов, в которой текст кнопок справа от изображения
    $TBSTYLE_CUSTOMERASE - Высылает сообщение $NM_CUSTOMDRAW, когда Toolbar обрабатывает сообщение $WM_ERASEBKGND.
    $TBSTYLE_REGISTERDROP - Высылает уведомление $TBN_GETOBJECT запрашивающее целевой объект перетаскивания.
    $TBSTYLE_TRANSPARENT - Создаёт прозрачную панель инструментов

См. также

_GUICtrlToolbar_GetStyle

Пример

#include <GuiToolbar.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

$Debug_TB = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает
Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $hToolbar
    Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp

    ; Создаёт GUI
    $hGUI = GUICreate(StringTrimRight(@ScriptName, 4), 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    $iMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 10, 400, 0, "Courier New")
    GUISetState()

    ; Устанавливает стиль Toolbar
    _GUICtrlToolbar_SetStyle($hToolbar, BitOR($TBSTYLE_LIST, $CCS_TOP))

    ; Добавляет стандартный системный bitmaps
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; Добавляет кнопки
    _GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; Показывает стиль Toolbar
    MemoWrite("Стиль Toolbar : 0x" & Hex(_GUICtrlToolbar_GetStyle($hToolbar)))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite