↑  ←  Описание функции

_GUICtrlRichEdit_SetParaSpacing

Sets paragraph spacing of paragraphs having selected text or, if none selected, sets it for text inserted at the insertion point

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetParaSpacing($hWnd, [$vInter=Default [, $iBefore=Default [, $iAfter=Default]]])

Параметры

$hWnd Дескриптор элемента
$vInter [необязательный] spacing between lines:
    either: a number - in space units
    or: " lines" - in lines
$iBefore [необязательный] spacing before paragraph(s) (in space units)
$iAfter [необязательный] spacing after paragraph(s) (in space units)

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False и устанавливает @error
@error:101 - $hWnd is not a handle
1021 - $vInter is invalid
1022 - Only 1, 1.5 and 2 line spacing can be set via " lines"
103 - $iBefore is neither a positive number nor zero
104 - $iAfter is neither a positive number nor zero

Примечания

Only settings which are not defaulted are set

To set "space units", call _GUICtrlRichEdit_SetSpaceUnit. Initially inches

См. также

_GUICtrlRichEdit_GetParaSpacing, _GUICtrlRichEdit_SetSpaceUnit

См. также

Искать EM_SETPARAFORMAT в библиотеке MSDN

Пример

#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $btnNext, $iStep = 0
    $hGui = GUICreate(StringTrimRight(@ScriptName, 4), 420, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, 'Это тест.', 10, 10, 400, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Далее", 270, 310, 60, 30)
    GUISetState()

    _GUICtrlRichEdit_SetText($hRichEdit, "First paragraph")
    Report("0. Para with default settings")

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit)
                GUIDelete()
                Exit
            Case $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_AppendText($hRichEdit, @CR & "Second paragraph")
                        _GUICtrlRichEdit_SetParaSpacing($hRichEdit, "2 lines", .2, .25)
                        Report("1. Spacing of second paragraph is ")
                    Case 2
                        _GUICtrlRichEdit_SetSel($hRichEdit, 0, 2)
                        Report("2. Settings of first paragraph in the selection are ")
                    Case 3
                        _GUICtrlRichEdit_SetSel($hRichEdit, 10, 26)
                        _GUICtrlRichEdit_SetParaSpacing($hRichEdit, Default, .1)
                        Report("3. Change spacing of both paragraphs")
                    Case 4
                        ; Stream all text to the Desktop so you can look at Indents settings in Word
                        _GUICtrlRichEdit_Deselect($hRichEdit)
                        _GUICtrlRichEdit_StreamToFile($hRichEdit, @DesktopDir & "\gcre.rtf")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSwitch
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    $sMsg &=  @cr & @cr & "get function returns " & @cr & _GUICtrlRichEdit_GetParaSpacing($hRichEdit)
    GUICtrlSetData($lblMsg, $sMsg)
    ControlFocus($hRichEdit, "", "")
EndFunc   ;==>Report