↑  ←  Описание функции

_GUICtrlRichEdit_GetParaSpacing

Gets the spacing settings of (first) selected paragraph or (if no selection) of the current paragraph

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetParaSpacing($hWnd)

Параметры

$hWnd Дескриптор элемента

Возвращаемое значение

Успех:a string consisting of the settings separated by semicolons (;):
value 1 - inter-line spacing:
either a number - in space units
or " lines" - in lines
Value 2 - scope of value 1:
a - all (or only) selected paragraph(s) have the above setting
f - the first selected paragraph has this setting, but other(s) don't
c - the current paragraph has this setting
value 3 - spacing before paragraphs (in space units)
value 4 - scope of value 3 - see above
value 5 - spacing after paragraphs (in space units)
value 6 - scope of value 5 - see above
Ошибка:Возвращает "" - пустую строку и устанавливает @error
@error:101 - $hWnd is not a handle

См. также

_GUICtrlRichEdit_SetParaSpacing

См. также

Искать EM_SETPARAFORMAT в библиотеке MSDN

Пример

#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $btnNext, $iStep = 0
    $hGui = GUICreate(StringTrimRight(@ScriptName, 4), 420, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, 'Это тест.', 10, 10, 400, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Далее", 270, 310, 60, 30)
    GUISetState()

    _GUICtrlRichEdit_SetText($hRichEdit, "First paragraph")
    Report("0. Para with default settings")

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit)
                GUIDelete()
                Exit
            Case $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_AppendText($hRichEdit, @CR & "Second paragraph")
                        _GUICtrlRichEdit_SetParaSpacing($hRichEdit, "2 lines", .2, .25)
                        Report("1. Spacing of second paragraph is ")
                    Case 2
                        _GUICtrlRichEdit_SetSel($hRichEdit, 0, 2)
                        Report("2. Settings of first paragraph in the selection are ")
                    Case 3
                        _GUICtrlRichEdit_SetSel($hRichEdit, 10, 26)
                        _GUICtrlRichEdit_SetParaSpacing($hRichEdit, Default, .1)
                        Report("3. Change spacing of both paragraphs")
                    Case 4
                        ; Stream all text to the Desktop so you can look at Indents settings in Word
                        _GUICtrlRichEdit_Deselect($hRichEdit)
                        _GUICtrlRichEdit_StreamToFile($hRichEdit, @DesktopDir & "\gcre.rtf")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSwitch
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    $sMsg &=  @cr & @cr & "get function returns " & @cr & _GUICtrlRichEdit_GetParaSpacing($hRichEdit)
    GUICtrlSetData($lblMsg, $sMsg)
    ControlFocus($hRichEdit, "", "")
EndFunc   ;==>Report