↑  ←  Описание функции

_GUICtrlRichEdit_SetText

Устанавливает текст в элемент

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetText($hWnd, $sText)

Параметры

$hWnd Дескриптор элемента
$sText Обычный или RTF текст вставляемый в элемент

Возвращаемое значение

Succcess:Возвращает True
Ошибка:Возвращает False, и устанавливает @error:
@error:101 - $HWnd не является дескриптором

Примечания

Устанавливает весь текст. Текст может быть простой или RTF.
Держит стек для отмены.

См. также

_GUICtrlRichEdit_GetText, _GUICtrlRichEdit_AppendText, _GUICtrlRichEdit_InsertText, _GUICtrlRichEdit_ReplaceText, _GUICtrlRichEdit_EmptyUndoBuffer

Пример

#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Main()

Func Main()
    Local $hGui, $hRichEdit
    $hGui = GUICreate(StringTrimRight(@ScriptName, 4), 420, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, 'Это тест.', 10, 10, 400, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    GUISetState()

    _GUICtrlRichEdit_SetText($hRichEdit, "Установленный текст")
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit)
                GUIDelete()
                Exit
        EndSwitch
    WEnd
EndFunc   ;==>Main