↑  ←  Описание функции

_GUICtrlRichEdit_ScrollToCaret

Прокрутить, чтобы показать строку, в которой текстовый курсор (позиция для вставки)

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_ScrollToCaret($hWnd)

Параметры

$hWnd Дескриптор элемента

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False и устанавливает @error
@error:101 - $HWnd не является дескриптором

См. также

_GUICtrlRichEdit_ScrollLineOrPage, _GUICtrlRichEdit_ScrollLines

См. также

Искать EM_SCROLLCARET в библиотеке MSDN

Пример

#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $btnNext, $iStep = 0
    $hGui = GUICreate(StringTrimRight(@ScriptName, 4), 420, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, 'Это тест.', 10, 10, 400, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Далее", 270, 310, 60, 30)
    GUISetState()

    For $i = 1 To 20
        _GUICtrlRichEdit_AppendText($hRichEdit, "Строка " & $i & @CR)
    Next
    _GUICtrlRichEdit_AppendText($hRichEdit, "Строка 21")

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit)
                GUIDelete()
                Exit
            Case $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_ScrollLineOrPage($hRichEdit, "pu")
                        Report("Прокручено вверх на страницу")
                    Case 2
                        _GUICtrlRichEdit_ScrollToCaret($hRichEdit)
                        Report("Прокручено к текстовому курсору")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSwitch
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    GUICtrlSetData($lblMsg, $sMsg)
    ControlFocus($hRichEdit, "", "")
EndFunc   ;==>Report