↑  ←  Описание функции

_GUICtrlRichEdit_ScrollLineOrPage

Прокручивает текст вверх или вниз на строку или на страницу

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_ScrollLineOrPage($hWnd, $sAction)

Параметры

$hWnd Дескриптор элемента
$sAction одно из следующих:
    "ld" - вниз на строку
    "lu" - вверх на строку
    "pd" - вниз на страницу
    "pu" - вверх на страницу

Возвращаемое значение

Успех:Возвращает количество строк, фактически прокрученных (положительное, если вниз)
Ошибка:Возвращает 0 и устанавливает @error
@error:101 - $HWnd не является дескриптором
1021 - $sAction не состоит из двух символов
1022 - первый символ должен быть l или p
1023 - второй символ должен быть d или u

Примечания

This function is well behaved: it never scrolls such that lines beyond the last one are shown.

См. также

_GUICtrlRichEdit_ScrollLines, _GUICtrlRichEdit_ScrollToCaret

См. также

Искать EM_SCROLL в библиотеке MSDN

Пример

#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $btnNext, $iStep = 0
    $hGui = GUICreate(StringTrimRight(@ScriptName, 4), 420, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, 'Это тест.', 10, 10, 400, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Далее", 270, 310, 60, 30)
    GUISetState()

    For $i = 1 To 20
        _GUICtrlRichEdit_AppendText($hRichEdit, "Строка " & $i & @CR)
    Next
    _GUICtrlRichEdit_AppendText($hRichEdit, "Строка 21")

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit)
                GUIDelete()
                Exit
            Case $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        DoIt("lu", "Прокручивает вверх на строку")
                    Case 2
                        DoIt("pu", "Прокручивает вверх на страницу")
                    Case 3
                        DoIt("pd", "Прокручивает вниз на страницу")
                    Case 4
                        DoIt("pd", "Попытка прокрутить вниз на другую страницу")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSwitch
    WEnd
EndFunc   ;==>Main

Func DoIt($sAction, $sMsg)
    Local $iQlines
    $iQlines = _GUICtrlRichEdit_ScrollLineOrPage($hRichEdit, $sAction)
    GUICtrlSetData($lblMsg, $sMsg & @CR & @CR & "Фактически прокручено " & $iQlines & " строк")
EndFunc   ;==>DoIt