↑  ←  Описание функции

_GUICtrlRichEdit_ScrollLines

Прокручивает текст вверх или вниз на указанное число строк

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_ScrollLines($hWnd, $iQlines)

Параметры

$hWnd Дескриптор элемента
$iQlines Число строк для прокрутки

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False и устанавливает @error
@error:101 - $HWnd не является дескриптором
102 - $iQlines не является числом
700 - попытка прокрутить однострочный элемент

Примечания

Чтобы прокрутить вниз установите $iQlines равным положительному числу. Чтобы прокрутить вверх - отрицательное число.

_GUICtrlRichEdit_ScrollLines is well behaved: if $iQlines is more than the number of lines below the current line, it scrolls to show only the last line; if $iQlines is negative and specifies a line before the first one, it scrolls to show the first line at the top of the control window.

См. также

_GUICtrlRichEdit_ScrollLineOrPage, _GUICtrlRichEdit_ScrollToCaret

См. также

Искать EM_LINESCROLL в библиотеке MSDN

Пример

#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $btnNext, $iStep = 0
    $hGui = GUICreate(StringTrimRight(@ScriptName, 4), 420, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, 'Это тест.', 10, 10, 400, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Далее", 270, 310, 60, 30)
    GUISetState()

    For $i = 1 To 20
        _GUICtrlRichEdit_AppendText($hRichEdit,"Строка " & $i & @CR)
    Next
    _GUICtrlRichEdit_AppendText($hRichEdit,"Строка 21")

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit)
                GUIDelete()
                Exit
            Case $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_ScrollLines($hRichEdit, -10.2)
                        Report("Прокручено вверх")
                    Case 2
                        _GUICtrlRichEdit_ScrollLines($hRichEdit, +100)
                        Report("Прокручено вниз так, чтобы отображалась только последняя строка")
                    Case 3
                        _GUICtrlRichEdit_ScrollLines($hRichEdit, -200)
                        Report("Прокручено вверх полностью")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSwitch
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    GUICtrlSetData($lblMsg, $sMsg)
    ControlFocus($hRichEdit, "", "")
EndFunc   ;==>Report