↑  ←  Описание функции

_GUICtrlRebar_SetBandStyle

Устанавливает флаги стилей ленты

#include <GuiReBar.au3>
_GUICtrlRebar_SetBandStyle($hWnd, $iIndex, $fStyle)

Параметры

$hwndRebar Дескриптор Rebar
$iIndex Индекс ленты, отсчёт от 0
$fStyle Стили, смотрите в структуре $tagREBARBANDINFO поле fStyle

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

См. также

_GUICtrlRebar_GetBandStyle, $tagREBARBANDINFO, _GUICtrlRebar_SetBandStyleBreak, _GUICtrlRebar_SetBandStyleChildEdge, _GUICtrlRebar_SetBandStyleFixedBMP, _GUICtrlRebar_SetBandStyleFixedSize, _GUICtrlRebar_SetBandStyleGripperAlways, _GUICtrlRebar_SetBandStyleHidden, _GUICtrlRebar_SetBandStyleHideTitle, _GUICtrlRebar_SetBandStyleNoGripper, _GUICtrlRebar_SetBandStyleTopAlign, _GUICtrlRebar_SetBandStyleUseChevron, _GUICtrlRebar_SetBandStyleVariableHeight

Пример

#include <GUIConstantsEx.au3>
#include <GuiReBar.au3>
#include <GuiToolbar.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

$Debug_RB = False

Global $iMemo

_Main()

Func _Main()
    Local $hgui, $hReBar, $hToolbar, $hInput
    Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp

    $hgui = GUICreate(StringTrimRight(@scriptname, 4), 400, 396, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_MAXIMIZEBOX))

    ; Создаёт элемент ReBar
    $hReBar = _GUICtrlRebar_Create($hgui, BitOR($CCS_TOP, $WS_BORDER, $RBS_VARHEIGHT, $RBS_AUTOSIZE, $RBS_BANDBORDERS))

    $iMemo = GUICtrlCreateEdit("", 2, 100, 396, 250, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 10, 400, 0, "Courier New")


    ; Создаёт элемент ToolBar, чтобы вставить его в ReBar
    $hToolbar = _GUICtrlToolBar_Create($hgui, BitOR($TBSTYLE_FLAT, $CCS_NORESIZE, $CCS_NOPARENTALIGN))

    ; Добавляет стандартный системный bitmaps
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; Добавляет кнопки
    _GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; Создаёт поле ввода, чтобы вставить его в ReBar
    $hInput = GUICtrlCreateInput("Поле ввода", 0, 0, 120, 20)

    ; Добавляет ленту содержащую элемент
    _GUICtrlRebar_AddBand($hReBar, GUICtrlGetHandle($hInput), 120, 200, "Заголовок:")

    ; Добавляет ленту, содержащую элемент, в начало ReBar
    _GUICtrlRebar_AddToolBarBand($hReBar, $hToolbar, "", 0)

    ; Устанавливает стили
    _GUICtrlRebar_SetBandStyle($hReBar, 1, BitOR($RBBS_CHILDEDGE, $RBBS_GRIPPERALWAYS, $RBBS_NOVERT))

    GUISetState(@SW_SHOW)

    For $x = 0 To _GUICtrlRebar_GetBandCount($hReBar) - 1
        MemoWrite("==== Используемые стили =====")
        MemoWrite("Индекс ленты " & $x & @tab & "fstyle: " & _GUICtrlRebar_GetBandStyle($hReBar, $x))
        MemoWrite("============================================")
        MemoWrite("$RBBS_BREAK.........: " & _GUICtrlRebar_GetBandStyleBreak($hReBar, $x))
        MemoWrite("$RBBS_CHILDEDGE.....: " & _GUICtrlRebar_GetBandStyleChildEdge($hReBar, $x))
        MemoWrite("$RBBS_FIXEDBMP......: " & _GUICtrlRebar_GetBandStyleFixedBMP($hReBar, $x))
        MemoWrite("$RBBS_FIXEDSIZE.....: " & _GUICtrlRebar_GetBandStyleFixedSize($hReBar, $x))
        MemoWrite("$RBBS_GRIPPERALWAYS.: " & _GUICtrlRebar_GetBandStyleGripperAlways($hReBar, $x))
        MemoWrite("$RBBS_HIDDEN........: " & _GUICtrlRebar_GetBandStyleHidden($hReBar, $x))
        MemoWrite("$RBBS_HIDETITLE.....: " & _GUICtrlRebar_GetBandStyleHideTitle($hReBar, $x))
        MemoWrite("$RBBS_NOGRIPPER.....: " & _GUICtrlRebar_GetBandStyleNoGripper($hReBar, $x))
        MemoWrite("$RBBS_NOVERT........: " & _GUICtrlRebar_GetBandStyleNoVert($hReBar, $x))
        MemoWrite("$RBBS_TOPALIGN......: " & _GUICtrlRebar_GetBandStyleTopAlign($hReBar, $x))
        MemoWrite("$RBBS_USECHEVRON....: " & _GUICtrlRebar_GetBandStyleUseChevron($hReBar, $x))
        MemoWrite("$RBBS_VARIABLEHEIGHT: " & _GUICtrlRebar_GetBandStyleVariableHeight($hReBar, $x))
    Next

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                Exit
        EndSwitch
    WEnd
EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite