↑  ←  Описание функции

_GUICtrlRebar_AddBand

Добавляет новую ленту в Rebar

#include <GuiReBar.au3>
_GUICtrlRebar_AddBand($hwndRebar, $hwndChild [, $iMinWidth = 100 [, $iDefaultWidth = 100 [, $sText = "" [, $iIndex = -1 [, $fStyle = -1]]]]])

Параметры

$hwndRebar Дескриптор Rebar
$hwndChild Дескриптор добавляемого элемента
$iMinWidth [необязательный] Минимальная ширина ленты
$iDefaultWidth [необязательный] Длина (ширина) ленты в пикселях
$sText [необязательный] Отображаемый текст на ленте
$iIndex [необязательный] Индекс-позиция, в которую лента будет вставлена, отсчёт от 0.
    Если этот параметр равен -1, то элемент будет добавлен в новую ленту в последнюю позицию
$fStyle [необязательный] Флаги, определяющие стиль ленты. Этот параметр может быть комбинацией следующих значений:
    $RBBS_BREAK - Помещает ленту на новую строку.
    $RBBS_CHILDEDGE - The band has an edge at the top and bottom of the child window.
    $RBBS_FIXEDBMP - Фоновый bitmap не перемещается при изменении размеров ленты.
    $RBBS_FIXEDSIZE - Размер ленты не может быть изменён. С этим стилем элемент захвата для изменения размера не отображается на ленте.
    $RBBS_GRIPPERALWAYS - Версия 4.71. Лента всегда отображает элемент захвата для изменения размера, даже если она единственная лента в Rebar.
    $RBBS_HIDDEN - Лента скрыта.
    $RBBS_NOGRIPPER - Версия 4.71. Лента никогда не отображает элемент захвата для изменения размера, даже если имеется более одной ленты в Rebar.
    $RBBS_USECHEVRON - Версия 5.80. Show a chevron button if the band is smaller than cxIdeal.
    $RBBS_VARIABLEHEIGHT - Версия 4.71. Размер ленты может изменится с помощью Rebar; cyIntegral и cyMaxChild affect how the rebar will resize the band.
    $RBBS_NOVERT - Don't show when vertical.
    $RBBS_USECHEVRON - Отображает drop-down кнопку.
    $RBBS_HIDETITLE - Скрывает заголовок ленты.
    $RBBS_TOPALIGN - Удерживает ленту на верхней строке.

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

См. также

_GUICtrlRebar_AddToolBarBand, _GUICtrlRebar_DeleteBand

Пример

#include <GuiReBar.au3>
#include <GuiComboBox.au3>
#include <GuiDateTimePicker.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>
#include <GUIConstantsEx.au3>

$Debug_RB = False

_Main()

Func _Main()
    Local $hgui, $hCombo, $hReBar, $hDTP, $hInput

    $hgui = GUICreate(StringTrimRight(@scriptname, 4), 400, 396, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_MAXIMIZEBOX))

    ; Создаёт элемент ReBar
    $hReBar = _GUICtrlRebar_Create($hgui, BitOR($CCS_TOP, $WS_BORDER, $RBS_VARHEIGHT, $RBS_AUTOSIZE, $RBS_BANDBORDERS))

    ; Создаёт раскрывающийся список, чтобы вставить его в ReBar
    $hCombo = _GUICtrlComboBox_Create($hgui, "", 0, 0, 120)

    _GUICtrlComboBox_BeginUpdate($hCombo)
    _GUICtrlComboBox_AddDir($hCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($hCombo)

    ; Создаёт элемент выбора даты и времени, чтобы вставить его в ReBar
    $hDTP = _GUICtrlDTP_Create($hgui, 0, 0, 190)

    ; Создаёт поле ввода, чтобы вставить его в ReBar
    $hInput = GUICtrlCreateInput("Поле ввода", 0, 0, 120, 20)

    ; Добавляет ленту в ReBar
    _GUICtrlRebar_AddBand($hReBar, $hCombo, 120, 200, "Dir *.exe")

    ; Добавляет ленту и делает её на второй строке
    _GUICtrlRebar_AddBand($hReBar, $hDTP, 120)
    _GUICtrlRebar_SetBandStyleBreak($hReBar, 1)

    ; Добавляет в начало ReBar
    _GUICtrlRebar_AddBand($hReBar, GUICtrlGetHandle($hInput), 120, 200, "Заголовок:", 0)

    GUISetState(@SW_SHOW)

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                Exit
        EndSwitch
    WEnd
EndFunc   ;==>_Main