↑  ←  Описание функции

_GUICtrlListView_SetBkImage

Устанавливает фоновый рисунок в ListView

#include <GuiListView.au3>
_GUICtrlListView_SetBkImage($hWnd [, $sURL = "" [, $iStyle = 0 [, $iXOffset = 0 [, $iYOffset = 0]]]])

Параметры

$hWnd Дескриптор или идентификатор элемента
$sURL [необязательный] URL или путь к рисунку. Если пустая строка, то ListView без фонового рисунка
$iStyle [необязательный] Определяет стиль фонового рисунка:
    0 - Обычный
    1 - Замостить плиткой
$iXOffset [необязательный] Процент клиентской области, на которое рисунок должен быть смещён по горизонтали. Верно только при использовании 0 в параметре $iStyle.
$iYOffset [необязательный] Процент клиентской области, на которое рисунок должен быть смещён по вертикали. Верно только при использовании 0 в параметре $iStyle.

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

Примечания

Вызывайте CoUninitialize (смотрите в примере), когда приложение завершает работу.
На данный момент эта функция работает только с _GUICtrlListView_Create или Внешних ListView.

См. также

_GUICtrlListView_Create, _GUICtrlListView_GetBkImage

Пример

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>

$Debug_LV = False ; Проверяет ClassName передаваемый в ListView функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

Example_UDF_Created() ; использует ListView на основе UDF

Func Example_UDF_Created()
    Local $GUI, $hImage, $aImage, $hListView

    $GUI = GUICreate("(UDF) ListView - Устанавливает фоновое изображение", 600, 550)
    ;=========================================================================================================
    $hListView = _GUICtrlListView_Create($GUI, "", 2, 2, 596, 500, -1, -1, True) ; Последний параметр вызывает CoInitializeEx
    ;=========================================================================================================
    _GUICtrlListView_SetExtendedListViewStyle($hListView, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_DOUBLEBUFFER))

    ; Загружает изображения
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x0000FF, 16, 16))
    _GUICtrlListView_SetImageList($hListView, $hImage, 1)

    ; Добавляет колонки
    _GUICtrlListView_InsertColumn($hListView, 0, "Колонка 1", 100)
    _GUICtrlListView_InsertColumn($hListView, 1, "Колонка 2", 100)
    _GUICtrlListView_InsertColumn($hListView, 2, "Колонка 3", 100)

    ; Добавляет пункты
    _GUICtrlListView_AddItem($hListView, "Стр 1: Кол 1", 0)
    _GUICtrlListView_AddSubItem($hListView, 0, "Стр 1: Кол 2", 1)
    _GUICtrlListView_AddSubItem($hListView, 0, "Стр 1: Кол 3", 2)
    _GUICtrlListView_AddItem($hListView, "Стр 2: Кол 1", 1)
    _GUICtrlListView_AddSubItem($hListView, 1, "Стр 2: Кол 2", 1)
    _GUICtrlListView_AddItem($hListView, "Стр 3: Кол 1", 2)

    ; Создание групп
    _GUICtrlListView_EnableGroupView($hListView)
    _GUICtrlListView_InsertGroup($hListView, -1, 1, "Группа 1")
    _GUICtrlListView_InsertGroup($hListView, -1, 2, "Группа 2")
    _GUICtrlListView_SetItemGroupID($hListView, 0, 1)
    _GUICtrlListView_SetItemGroupID($hListView, 1, 2)
    _GUICtrlListView_SetItemGroupID($hListView, 2, 2)

;~  _GUICtrlListView_SetBkColor ($hListView, $CLR_NONE)
;~  _GUICtrlListView_SetTextColor ($hListView, $CLR_NONE)
;~  _GUICtrlListView_SetTextBkColor ($hListView, $CLR_NONE)

    ; Скачивает изображение
    Local $sURL = "http://www.autoitscript.com/autoit3/files/graphics/autoit9_wall_grey_800x600.jpg"
    Local $sFilePath = @ScriptDir & "\AutoIt.jpg"
    InetGet($sURL, $sFilePath)

    ; Устанавливает фоновое изображение
    _GUICtrlListView_SetBkImage($hListView, $sFilePath)
    $aImage = _GUICtrlListView_GetBkImage($hListView)

    GUISetState()

    MsgBox(4160, "Информация", "Фоновое изображение:" & @LF & @LF & $aImage[1])

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    ;=========================================================================================================
    DllCall('ole32.dll', 'long', 'CoUinitialize') ; Необходимо вызвать для каждого сделанного вызова CoInitializeEx
    ;=========================================================================================================

    GUIDelete()
    FileDelete($sFilePath)
EndFunc   ;==>Example_UDF_Created