Функция _GUICtrlListView

_GUICtrlListView_EnableGroupView

Разрешает или запрещает отображать пункты ListView группами

#include <GuiListView.au3>
_GUICtrlListView_EnableGroupView($hWnd [, $fEnable = True])

Параметры

$hWnd	Дескриптор или идентификатор элемента
$fEnable	[необязательный] Указывает, следует ли разрешить отображение пунктов в группах True - Разрешает показывать группы False - Запрещает показывать группы

Возвращаемое значение

0: Способность отображать пункты ListView как группы уже разрешено или уже запрещено (изменение не произошло)
1: Состояние ListView успешно изменено

Примечания

Минимальная ОС - Windows XP.

Эта функция не поддерживается под стилем $LVS_OWNERDATA.

См. также

_GUICtrlListView_GetGroupViewEnabled

Пример

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>

$Debug_LV = False ; Проверяет ClassName передаваемый в ListView функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
Local $hImage, $hListView

GUICreate("ListView Вкл/Выкл показ групп", 400, 300)
$hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
GUISetState()

; Загружает изображения
$hImage = _GUIImageList_Create()
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap(GUICtrlGetHandle($hListView), 0xFF0000, 16, 16))
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap(GUICtrlGetHandle($hListView), 0x00FF00, 16, 16))
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap(GUICtrlGetHandle($hListView), 0x0000FF, 16, 16))
_GUICtrlListView_SetImageList($hListView, $hImage, 1)

; Добавляет колонки
_GUICtrlListView_InsertColumn($hListView, 0, "Колонка 1", 120)
_GUICtrlListView_InsertColumn($hListView, 1, "Колонка 2", 100)
_GUICtrlListView_InsertColumn($hListView, 2, "Колонка 3", 100)

; Добавляет пункты
_GUICtrlListView_AddItem($hListView, "Стр 1: Кол 1", 0)
_GUICtrlListView_AddSubItem($hListView, 0, "Стр 1: Кол 2", 1)
_GUICtrlListView_AddSubItem($hListView, 0, "Стр 1: Кол 3", 2)
_GUICtrlListView_AddItem($hListView, "Стр 2: Кол 1", 1)
_GUICtrlListView_AddSubItem($hListView, 1, "Стр 2: Кол 2", 1)
_GUICtrlListView_AddItem($hListView, "Стр 3: Кол 1", 2)

; Создание групп
_GUICtrlListView_EnableGroupView($hListView)
_GUICtrlListView_InsertGroup($hListView, -1, 1, "Группа 1")
_GUICtrlListView_InsertGroup($hListView, -1, 2, "Группа 2")
_GUICtrlListView_SetItemGroupID($hListView, 0, 1)
_GUICtrlListView_SetItemGroupID($hListView, 1, 2)
_GUICtrlListView_SetItemGroupID($hListView, 2, 2)

; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main