Функция _GUICtrlListView

_GUICtrlListView_GetGroupInfoByIndex

Возвращает информацию о группе

#include <GuiListView.au3>
_GUICtrlListView_GetGroupInfoByIndex($hWnd, $iIndex)

Параметры

$hWnd	Дескриптор или идентификатор элемента
$iIndex	Индекс группы, информацию которой необходимо извлечь

Возвращаемое значение

Возвращает массив следующего формата:
        [0] - Текст заголовка
        [1] - Выравнивание заголовка:
        0 - Левое
        1 - По центру
        2 - Правое

Примечания

Минимальная операционная система: Windows Vista

См. также

_GUICtrlListView_SetGroupInfo, _GUICtrlListView_GetGroupInfo

Пример

If @osversion = "WIN_XP" And MsgBox(4160 + 4 + 256, "Информация", "Эта функция не работает в WinXP" & @lf & "продолжить?") = 7 Then Exit
#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>

$Debug_LV = False ; Проверяет ClassName передаваемый в ListView функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
Local $aInfo, $hImage, $hListView

GUICreate("Получает информацию о группе", 400, 300)

$hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
GUISetState()

; Загружает изображения
$hImage = _GUIImageList_Create()
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap(GUICtrlGetHandle($hListView), 0xFF0000, 16, 16))
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap(GUICtrlGetHandle($hListView), 0x00FF00, 16, 16))
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap(GUICtrlGetHandle($hListView), 0x0000FF, 16, 16))
_GUICtrlListView_SetImageList($hListView, $hImage, 1)

; Добавляет колонки
_GUICtrlListView_AddColumn($hListView, "Колонка 1", 120)
_GUICtrlListView_AddColumn($hListView, "Колонка 2", 100)
_GUICtrlListView_AddColumn($hListView, "Колонка 3", 100)

; Добавляет пункты
_GUICtrlListView_AddItem($hListView, "Стр 1: Кол 1", 0)
_GUICtrlListView_AddSubItem($hListView, 0, "Стр 1: Кол 2", 1)
_GUICtrlListView_AddSubItem($hListView, 0, "Стр 1: Кол 3", 2)
_GUICtrlListView_AddItem($hListView, "Стр 2: Кол 1", 1)
_GUICtrlListView_AddSubItem($hListView, 1, "Стр 2: Кол 2", 1)
_GUICtrlListView_AddItem($hListView, "Стр 3: Кол 1", 2)

; Создание групп
_GUICtrlListView_EnableGroupView($hListView)
_GUICtrlListView_InsertGroup($hListView, -1, 1, "Группа 1", 1)
_GUICtrlListView_InsertGroup($hListView, -1, 2, "Группа 2")
_GUICtrlListView_SetItemGroupID($hListView, 0, 1)
_GUICtrlListView_SetItemGroupID($hListView, 1, 2)
_GUICtrlListView_SetItemGroupID($hListView, 2, 2)

; Изменяет информацию о группе (работает на Vista и выше)
For $x = 0 To _GUICtrlListView_GetGroupCount($hListView) - 1
$aInfo = _GUICtrlListView_GetGroupInfoByIndex($hListView, $x)
MsgBox(4160, "Информация", "Индекс " & $x + 1 & "Текст: " & $aInfo[0])
Next

; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

GUIDelete()
EndFunc ;==>_Main