↑  ←  Описание функции

_GDIPlus_GraphicsCreateFromHDC

Создаёт графический объект из контекст устройства (DC)

#include <GDIPlus.au3>
_GDIPlus_GraphicsCreateFromHDC($hDC)

Параметры

$hDC Контекст устройства

Возвращаемое значение

Успех:Возвращает дескриптор графического объекта
Ошибка:Возвращает 0

Примечания

При завершении использования графического объекта, необходимо вызвать функцию _GDIPlus_GraphicsDispose, чтобы освободить ресурсы.

См. также

_GDIPlus_GraphicsDispose

См. также

Искать GdipCreateFromHDC в библиотеке MSDN

Пример

#include <GUIConstantsEx.au3>
#include <GDIPlus.au3>
#include <WinAPI.au3>

_Main()

Func _Main()
    Local $hGUI, $hGraphic, $hBrush, $hFormat, $hFamily, $hFont, $tLayout, $hDC

    ; Создаёт GUI
    $hGUI = GUICreate("GDI+", 400, 300)
    $hDC  = _WinAPI_GetWindowDC($hGUI)
    GUISetState()

    ; Рисует строку
    _GDIPlus_Startup ()
    $hGraphic = _GDIPlus_GraphicsCreateFromHDC ($hDC)
    $hBrush = _GDIPlus_BrushCreateSolid (0x7F00007F)
    $hFormat = _GDIPlus_StringFormatCreate ()
    $hFamily = _GDIPlus_FontFamilyCreate ("Arial")
    $hFont = _GDIPlus_FontCreate ($hFamily, 12, 2)
    $tLayout = _GDIPlus_RectFCreate (140, 110, 140, 20)
    _GDIPlus_GraphicsDrawStringEx ($hGraphic, "Привет мир", $hFont, $tLayout, $hFormat, $hBrush)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Очищает ресурсы
    _GDIPlus_FontDispose ($hFont)
    _GDIPlus_FontFamilyDispose ($hFamily)
    _GDIPlus_StringFormatDispose ($hFormat)
    _GDIPlus_BrushDispose ($hBrush)
    _GDIPlus_GraphicsDispose ($hGraphic)
    _WinAPI_ReleaseDC($hGUI, $hDC)
    _GDIPlus_Shutdown ()

EndFunc   ;==>_Main