↑  ←  Описание функции

_GDIPlus_BrushCreateSolid

Создаёт объект - Сплошная Кисть

#include <GDIPlus.au3>
_GDIPlus_BrushCreateSolid([$iARGB = 0xFF000000])

Параметры

$iARGB [необязательный] Компоненты цвета кисти - альфа (прозрачность), красный, зелёный, синий

Возвращаемое значение

Успех:Возвращает дескриптор объекта Кисть
Ошибка:Возвращает 0

Примечания

Когда вы закончили использование объект Кисть, вызовите _GDIPlus_BrushDispose, чтобы освободить ресурсы

См. также

_GDIPlus_BrushDispose

См. также

Искать GdipCreateSolidFill в библиотеке MSDN

Пример

#include <GUIConstantsEx.au3>
#include <GDIPlus.au3>
#include <WindowsConstants.au3>

Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $hBrush1, $hBrush2

    ; Создаёт GUI
    $hGUI = GUICreate("GDI+", 400, 300)
    $iMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; Создаёт кисть
    _GDIPlus_Startup ()
    $hBrush1 = _GDIPlus_BrushCreateSolid ()
    $hBrush2 = _GDIPlus_BrushClone ($hBrush1)

    ; Показывает информацию кисти
    MemoWrite("Brush 1 handle : 0x" & Hex($hBrush1))
    MemoWrite("Brush 1 type ..: " & _GDIPlus_BrushGetType ($hBrush1))
    MemoWrite("Brush 2 handle : 0x" & Hex($hBrush2))
    MemoWrite("Brush 2 type ..: " & _GDIPlus_BrushGetType ($hBrush2))

    ; Очищает ресурсы
    _GDIPlus_BrushDispose ($hBrush2)
    _GDIPlus_BrushDispose ($hBrush1)
    _GDIPlus_ShutDown ()

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage = '')
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite