↑  ←  Описание функции

_GDIPlus_StringFormatCreate

Создаёт объект String Format

#include <GDIPlus.au3>
_GDIPlus_StringFormatCreate([$iFormat = 0 [, $iLangID = 0]])

Параметры

$iFormat [необязательный] Флаги формата. Может быть комбинацией следующих значений:
    0x0001 - Указывает, что порядок чтения справа налево
    0x0002 - Указывает, что отдельные строки текста рисуются вертикально на отображающем устройстве
    0x0004 - Указывает, что частям символов разрешается выступать за границы прямоугольника строки
    0x0020 - Указывает, что управляющие символы Unicode отображаются представительными символами
    0x0400 - Указывает, что альтернативный шрифт используемый для символов не поддерживается в требуемом шрифте
    0x0800 - Указывает, что пробелы в конце каждой строки учитываются при измерении длины строки
    0x1000 - Указывает, что перенос текста на следующую строку отключен
    0x2000 - Указывает, что только целые строки располагаются в прямоугольнике
    0x4000 - Указывает, что символы выступающие за границы прямоугольника и текст выходящий за пределы прямоугольника разрешается отображать
$iLangID [необязательный] Используемый язык

Возвращаемое значение

Успех:Возвращает дескриптор объекта String Format
Ошибка:Возвращает 0

Примечания

При завершении использования объекта String Format, необходимо вызвать функцию _GDIPlus_StringFormatDispose, чтобы освободить ресурсы.

См. также

_GDIPlus_StringFormatDispose, _GDIPlus_StringFormatSetAlign

См. также

Искать GdipCreateStringFormat в библиотеке MSDN

Пример

#include <GUIConstantsEx.au3>
#include <GDIPlus.au3>

_Main()

Func _Main()
    Local $hGUI, $hGraphic, $hBrush, $hFormat, $hFamily, $hFont, $tLayout

    ; Создаёт GUI
    $hGUI = GUICreate("GDI+", 400, 300)
    GUISetState()

    ; Рисует строку
    _GDIPlus_Startup ()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND ($hGUI)
    $hBrush = _GDIPlus_BrushCreateSolid (0xFF00007F)
    $hFormat = _GDIPlus_StringFormatCreate ()
    $hFamily = _GDIPlus_FontFamilyCreate ("Arial")
    $hFont = _GDIPlus_FontCreate ($hFamily, 12, 2)
    $tLayout = _GDIPlus_RectFCreate (140, 110, 140, 20)
    _GDIPlus_GraphicsDrawStringEx ($hGraphic, "Привет мир", $hFont, $tLayout, $hFormat, $hBrush)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Очищает ресурсы
    _GDIPlus_FontDispose ($hFont)
    _GDIPlus_FontFamilyDispose ($hFamily)
    _GDIPlus_StringFormatDispose ($hFormat)
    _GDIPlus_BrushDispose ($hBrush)
    _GDIPlus_GraphicsDispose ($hGraphic)
    _GDIPlus_ShutDown ()

EndFunc   ;==>_Main