ввод последовательных значений из IE в массив

[Alexaut]

Пробую вытаскивать адреса иконок со странички - вроде, получается, - ArrayDisplay отобранные иконки ПОСЛЕДОВАТЕЛЬНО показывает.

#include "IE.au3"
#include "Array.au3"

$sUrl = "http://www.photosight.ru/users/208022/"

$oIE = _IECreate($sUrl)
$oMetas = _IETagNameGetCollection ($oIE, "img")
For $oMeta In $oMetas
    If $oMeta.src <> "0" then
		If StringRight($oMeta.src,3) = "jpg" or StringRight($oMeta.src,4) = "jpeg" Then
           
$avArray = _ArrayCreate($oMeta.src)
			
			_ArrayDisplay( $avArray, "Адрес иконки" )
			
      EndIf  
    EndIf
Next

- А как создать массив включающий всю СОВОКУПНОСТЬ отобранных иконок?

 

[axlwor]

#include "IE.au3"
#include "Array.au3"

$sUrl = "http://www.photosight.ru/users/208022/"

$oIE = _IECreate($sUrl)
$sHTML = _IEDocReadHTML($oIE)
$sPattern = '(?i)src=["''](http.*?\.jp[ge]+)'
$aA = StringRegExp($sHTML, $sPattern, 3)
_ArrayDisplay($aA)

 

[madmasles]

Alexaut,
Можно и так попробовать.

#include <IE.au3>
#include <Array.au3>

$sUrl = 'http://www.photosight.ru/users/208022/'
$iCount = 0
$oIE = _IECreate($sUrl)
$oMetas = _IETagNameGetCollection($oIE, 'img')
Dim $aIMG[@extended + 1][2]
For $oMeta In $oMetas
	If StringRegExp($oMeta.src, '\.jp[eg]{1,2}$') Then
		$iCount += 1
		$aIMG[$iCount][0] = $oMeta.src
		$aIMG[$iCount][1] = $oMeta.alt
	EndIf
Next
If $iCount Then
	ReDim $aIMG[$iCount + 1][2]
	$aIMG[0][0] = $iCount
	_ArrayDisplay($aIMG)
Else
	MsgBox(16, 'Error', 'Error')
EndIf

{CodeWarn}

 

[Alexaut]

axlwor
madmasles

Оба варианта работают. - СПАСИБО!

 

[kaster]

Alexaut [?]

Оба варианта работают. - СПАСИБО!

а на предупреждение кто будет реагировать?

 

[Alexaut]

Kaster

Вы про код AutoIt? - не знал, что сообщение можно корректировать. - Поменял