↑  ←  Описание функции

_WinAPI_SetEndOfFile

Устанавливает физический размер указанного файла по текущей позиции файлового указателя.

#include <WinAPI.au3>
_WinAPI_SetEndOfFile($hFile)

Параметры

$hFile Дескриптор файла, который будет обрезан или увеличен. Дескриптор файла должен иметь права доступа $GENERIC_WRITE.

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False, @extended содержит результат GetLastError() для получения деталей ошибки

Примечания

Эта функция может использоваться для обрезки или увеличения файла.
Если файл увеличен, то содержание файла между старым концом файла и новым концом файла не определено.
Эта функция устанавливает размер файла.

См. также

_WinAPI_CloseHandle, _WinAPI_CreateFile, _WinAPI_FlushFileBuffers, _WinAPI_GetFileSizeEx, _WinAPI_ReadFile, _WinAPI_SetFilePointer, _WinAPI_WriteFile

См. также

Искать SetEndOfFile в библиотеке MSDN

Пример


#include <WinAPI.au3>

Global $sFile, $hFile, $sText, $nBytes, $tBuffer

; 1) Создаёт файл и записывает данные в него
$sFile = @ScriptDir & '\test.txt'
$sText = 'abcdefghijklmnopqrstuvwxyz'
$tBuffer = DllStructCreate("byte[" & StringLen($sText) & "]")
DllStructSetData($tBuffer, 1, $sText)
$hFile = _WinAPI_CreateFile($sFile, 1)
_WinAPI_WriteFile($hFile, DllStructGetPtr($tBuffer), StringLen($sText), $nBytes)
_WinAPI_CloseHandle($hFile)
ConsoleWrite('1) ' & FileRead($sFile) & @CRLF)

; 2) Читает 6 байтов из позиции 3
$tBuffer = DllStructCreate("byte[6]")
$hFile = _WinAPI_CreateFile($sFile, 2, 2)
_WinAPI_SetFilePointer($hFile, 3)
_WinAPI_ReadFile($hFile, DllStructGetPtr($tBuffer), 6, $nBytes)
_WinAPI_CloseHandle($hFile)
$sText = BinaryToString(DllStructGetData($tBuffer, 1))
ConsoleWrite('2) ' & $sText & @CRLF)

; 3) Записывает предыдущие прочитанные 6 байтов из позиции 3, в ту же позицию, но в верхнем регистре
DllStructSetData($tBuffer, 1, StringUpper($sText))
$hFile = _WinAPI_CreateFile($sFile, 2, 4)
_WinAPI_SetFilePointer($hFile, 3)
_WinAPI_WriteFile($hFile, DllStructGetPtr($tBuffer), 6, $nBytes)
_WinAPI_CloseHandle($hFile)
$tBuffer = 0
ConsoleWrite('3) ' & FileRead($sFile) & @CRLF)

; 4) Обрезает размер файла до 12 байт
$hFile = _WinAPI_CreateFile($sFile, 2, 4)
_WinAPI_SetFilePointer($hFile, 12)
_WinAPI_SetEndOfFile($hFile)
_WinAPI_CloseHandle($hFile)
ConsoleWrite('4) ' & FileRead($sFile) & @CRLF)