↑  ←  Описание функции

_GUIImageList_GetIconSizeEx

Возвращает размер изображений находящихся в списке изображений

#include <GuiImageList.au3>
_GUIImageList_GetIconSizeEx($hWnd)

Параметры

$hWnd Дескриптор ImageList

Возвращаемое значение

Успех:Возвращает структуру $tagPOINT
Ошибка:Возвращает 0

Примечания

Все изображения в списке изображений имеют одинаковые размеры

См. также

_GUIImageList_GetIconHeight, _GUIImageList_GetIconSize, _GUIImageList_GetIconWidth

Пример

#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
#include <GuiImageList.au3>

Global $iMemo

_Main()

Func _Main()
    Local $hImage, $hGUI, $hDC, $tSize

    $hGUI = GUICreate("Получает размеры иконки списка изображений", 400, 300)
    $iMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; Загружает изображения
    $hImage = _GUIImageList_Create(32, 24)
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0xFF0000, 32, 24))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x00FF00, 32, 24))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x0000FF, 32, 24))

    ; Рисует изображение
    $hDC = _WinAPI_GetDC($hGUI)
    _GUIImageList_Draw($hImage, 0, $hDC, 4, 4)
    _GUIImageList_Draw($hImage, 1, $hDC, 40, 4)
    _GUIImageList_Draw($hImage, 2, $hDC, 76, 4)

    _WinAPI_ReleaseDC($hGUI, $hDC)

    ; Показывает размер иконок списка изображений
    $tSize = _GUIImageList_GetIconSizeEx($hImage)
    MemoWrite("Ширина изображения: " & DllStructGetData($tSize, "X"))
    MemoWrite("Высота изображения: " & DllStructGetData($tSize, "Y"))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite