_GUIImageList_DrawEx
Рисует изображение списка изображений в указанном контекст устройстве
#include <GuiImageList.au3>
_GUIImageList_DrawEx($hWnd, $iIndex, $hDC, $iX, $iY [, $iDX = 0 [, $iDY = 0 [, $iRGBBk = 0xFFFFFFFF [, $iRGBFg = 0xFFFFFFFF [, $iStyle=0]]]]])
Параметры
| $hWnd | Дескриптор ImageList |
| $iIndex |
Индекс изображение, отсчёт от 0 |
| $hDC |
Дескриптор контекст устройства |
| $iX |
X-координата, где будет располагаться изображение |
| $iY |
Y-координата, где будет располагаться изображение |
| $iDX |
[необязательный] Ширина изображения нарисованного относительно левого верхнего угла изображения. Если $iDX и $iDY равны 0, то функция нарисует изображение целиком. Функция не проверяет, что параметры верны. |
| $iDY |
[необязательный] Высота изображения нарисованного относительно левого верхнего угла изображения. Если $iDX и $iDY равны 0, то функция нарисует изображение целиком. Функция не проверяет, что параметры верны. |
| $iRGBBk |
[необязательный] The background color of the image. This parameter can be an application-defined RGB value or one of the following values: $CLR_NONE - No background color. The image is drawn transparently. $CLR_DEFAULT - The default background color. The image is drawn using the background color of the image list. |
| $iRGBFg |
[необязательный] The foreground color of the image. This parameter can be an application-defined RGB value or one of the following values: $CLR_NONE - No blend color. The image is blended with the color of the destination device context. $CLR_DEFAULT - The default foreground color. The image is drawn using the system highlight color as the foreground color. |
| $iStyle |
[необязательный] Drawing style and overlay image: 1 - Draws the image transparently using the mask, regardless of the background color 2 - Draws the image, blending 25 percent with the system highlight color 4 - Draws the image, blending 50 percent with the system highlight color 8 - Draws the mask |
Возвращаемое значение
| Успех: | Возвращает True |
| Ошибка: | Возвращает False |
См. также
_GUIImageList_DrawПример
#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
#include <GuiImageList.au3>
_Main()
Func _Main()
Local $hImage, $hGUI, $hDC
Local $Wow64
If @autoitx64 Then $Wow64 = "\Wow6432Node"
Local $AutoItDir = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $Wow64 & "\AutoIt v3\AutoIt", "InstallDir")
$hGUI = GUICreate("Рисует в контекст устройстве", 400, 300)
GUISetState()
; Загружает изображения
; Создаёт список изображений
$hImage = _GUIImageList_Create(48, 48, 5, 3)
; Добавляет иконки
_GUIImageList_AddIcon($hImage, $AutoItDir & "\Icons\au3.ico")
_GUIImageList_AddIcon($hImage, $AutoItDir & "\Icons\au3script_v9.ico")
_GUIImageList_AddIcon($hImage, $AutoItDir & "\Icons\au3script_v10.ico")
_GUIImageList_AddIcon($hImage, $AutoItDir & "\Icons\filetype-blank.ico")
_GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0xFF0000, 48, 48))
_GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x00FF00, 48, 48))
_GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x0000FF, 48, 48))
; Рисует изображение
$hDC = _WinAPI_GetDC($hGUI)
_GUIImageList_DrawEx($hImage, 0, $hDC, 4, 4, 16, 16)
_GUIImageList_DrawEx($hImage, 1, $hDC, 60, 4, 32, 32)
_GUIImageList_DrawEx($hImage, 2, $hDC, 120, 4, 64, 32)
_GUIImageList_DrawEx($hImage, 2, $hDC, 120, 50, 32, 64)
_GUIImageList_DrawEx($hImage, 3, $hDC, 180, 4, 64, 64)
_GUIImageList_DrawEx($hImage, 4, $hDC, 4, 150, 10, 48)
_GUIImageList_DrawEx($hImage, 5, $hDC, 64, 150, 48, 10)
_GUIImageList_DrawEx($hImage, 6, $hDC, 124, 150, 24, 32)
_WinAPI_ReleaseDC($hGUI, $hDC)
; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main