_GUICtrlTreeView_SetCheckedByIndex
Устанавливает или снимает галочку пункта с checkbox по указанному индексу
#include <GuiTreeView.au3>
_GUICtrlTreeView_SetCheckedByIndex($hWnd, $hItem, $iIndex [, $fCheck = True])
Параметры
| $hWnd | Дескриптор или идентификатор элемента |
| $hItem |
Дескриптор родительского пункта |
| $iIndex |
Индекс дочернего пункта по отношению к $hItem, отсчёт от 0 |
| $fCheck |
[необязательный] Устанавливаемое состояние: True - установить галочку False - убрать галочку |
Возвращаемое значение
| Успех: | Возвращает True |
| Ошибка: | Возвращает False |
Пример
#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>
$Debug_TV = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает
_Main()
Func _Main()
Local $hItem[6], $hRandomItem, $iRandIndex, $hTreeView
Local $iStyle = BitOR($TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
GUICreate("Устанавливает галочку по индексу", 400, 300)
$hTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
GUISetState()
_GUICtrlTreeView_BeginUpdate($hTreeView)
For $x = 0 To UBound($hItem) - 1
$hItem[$x] = GUICtrlCreateTreeViewItem('[' & $x & '] Пункт', $hTreeView)
For $y = 0 To 5
GUICtrlCreateTreeViewItem('[' & $y & '] Дочерний', $hItem[$x])
Next
Next
_GUICtrlTreeView_EndUpdate($hTreeView)
$hRandomItem = Random(0, UBound($hItem) - 1, 1)
$iRandIndex = Random(0, 5, 1)
_GUICtrlTreeView_Expand($hTreeView, $hItem[$hRandomItem])
MsgBox(4160, "Информация", _
'Устанавливает галочку в дочерний пункт с индексом [' & $iRandIndex & '],' & @LF & _
'содержащийся в родительском пункте с индексом [' & $hRandomItem & ']: ' & _
_GUICtrlTreeView_SetCheckedByIndex($hTreeView, $hItem[$hRandomItem], $iRandIndex))
; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc