_GUICtrlTreeView_Expand
Разворачивает или сворачивает список вложенных пунктов, если имеются.
#include <GuiTreeView.au3>
_GUICtrlTreeView_Expand($hWnd [, $hItem = 0 [, $fExpand = True]])
Параметры
| $hWnd | Дескриптор или идентификатор элемента |
| $hItem |
[необязательный] Дескриптор пункта. Если не указан, то применяется к дереву. |
| $fExpand |
[необязательный] Для разворачивания или сворачивания используются следующие значения: True - Разворачивает пункт False - Сворачивает пункт |
См. также
_GUICtrlTreeView_ExpandedOnce, _GUICtrlTreeView_GetExpandedПример
#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>
$Debug_TV = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает
_Main()
Func _Main()
Local $hItem[5], $hTreeView
Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
GUICreate("TreeView - Развернуть/Свернуть", 400, 300)
$hTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
GUISetState()
_GUICtrlTreeView_BeginUpdate($hTreeView)
For $x = 0 To 4
$hItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] Пункт", $x), $hTreeView)
For $y = 0 To 2
GUICtrlCreateTreeViewItem(StringFormat("[%02d] Дочерний", $y), $hItem[$x])
Next
Next
_GUICtrlTreeView_EndUpdate($hTreeView)
MsgBox(4160, "Информация", "Развернуть все")
_GUICtrlTreeView_Expand($hTreeView)
MsgBox(4160, "Информация", "Свернуть все")
_GUICtrlTreeView_Expand($hTreeView, 0, False)
MsgBox(4160, "Информация", "Развернуть пункт 0")
_GUICtrlTreeView_Expand($hTreeView, $hItem[0])
MsgBox(4160, "Информация", "Свернуть пункт 0")
_GUICtrlTreeView_Expand($hTreeView, $hItem[0], False)
; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main