_GUICtrlToolbar_SetButtonStyle
Устанавливает стиль кнопки
#include <GuiToolBar.au3>
_GUICtrlToolbar_SetButtonStyle($hWnd, $iCommandID, $iStyle)
Параметры
| $hWnd | Дескриптор элемента |
| $iCommandID |
Идентификатор кнопки |
| $iStyle |
Стили кнопки. Это может быть комбинацией следующих значений: $BTNS_AUTOSIZE - Toolbar не должен назначать стандартную ширину кнопок $BTNS_CHECK - Переключает между нажатым и отжатым положением $BTNS_CHECKGROUP - Кнопка остаётся нажатой до тех пор, пока не будет нажата иная кнопка в группе $BTNS_DROPDOWN - Создаёт кнопку со стилем раскрывающегося вниз списка $BTNS_GROUP - Кнопка остаётся нажатой до тех пор, пока не будет нажата иная кнопка в группе $BTNS_NOPREFIX - Текст кнопки не будет иметь префикс быстрой клавиши $BTNS_SEP - Создаёт разделитель $BTNS_SHOWTEXT - Указывает, что текст кнопки должен отображаться $BTNS_WHOLEDROPDOWN - Указывает, что кнопка будет иметь стрелку раскрывающегося списка |
Возвращаемое значение
| Успех: | Возвращает True |
| Ошибка: | Возвращает False |
См. также
_GUICtrlToolbar_GetButtonStyleПример
#include <GuiToolbar.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>
$Debug_TB = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает
Global $iMemo
_Main()
Func _Main()
Local $hGUI, $hToolbar
Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp
; Создаёт GUI
$hGUI = GUICreate(StringTrimRight(@ScriptName, 4), 400, 300)
$hToolbar = _GUICtrlToolbar_Create($hGUI)
$iMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
GUICtrlSetFont($iMemo, 10, 400, 0, "Courier New")
GUISetState()
; Добавляет стандартный системный bitmaps
Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
Case 0
_GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
Case 2
_GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
EndSwitch
; Добавляет кнопки
_GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW)
_GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN)
_GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE)
_GUICtrlToolbar_AddButtonSep($hToolbar)
_GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)
; Устанавливает стиль кнопки "Save"
_GUICtrlToolbar_SetButtonStyle($hToolbar, $idSave, $BTNS_CHECK)
; Показывает стиль кнопки "Save"
MemoWrite('Стиль кнопки "Save": ' & _GUICtrlToolbar_GetButtonStyle($hToolbar, $idSave))
; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main
; Записывает строку в элемент для заметок
Func MemoWrite($sMessage = "")
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite