_GUICtrlToolbar_SetButtonState
Устанавливает состояние указанной кнопки
#include <GuiToolBar.au3>
_GUICtrlToolbar_SetButtonState($hWnd, $iCommandID, $iState)
Параметры
| $hWnd | Дескриптор элемента |
| $iCommandID |
Идентификатор кнопки |
| $iState |
Состояние кнопки. Это может быть комбинацией следующих значений: $TBSTATE_CHECKED - Кнопка имеет стиль $TBSTYLE_CHECK и вид нажатой кнопки $TBSTATE_PRESSED - Нажатая кнопка $TBSTATE_ENABLED - Кнопка доступна $TBSTATE_HIDDEN - Кнопка скрыта $TBSTATE_INDETERMINATE - Кнопка серая $TBSTATE_WRAP - Кнопка сопровождается переносом на новую строку кнопок $TBSTATE_ELLIPSES - Текст кнопки обрезается и отображается многоточие $TBSTATE_MARKED - The button is marked |
Возвращаемое значение
| Успех: | Возвращает True |
| Ошибка: | Возвращает False |
См. также
_GUICtrlToolbar_GetButtonStateПример
#include <GuiToolbar.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>
$Debug_TB = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает
Global $iMemo
_Main()
Func _Main()
Local $hGUI, $hToolbar
Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp
; Создаёт GUI
$hGUI = GUICreate(StringTrimRight(@ScriptName, 4), 400, 300)
$hToolbar = _GUICtrlToolbar_Create($hGUI)
$iMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
GUICtrlSetFont($iMemo, 10, 400, 0, "Courier New")
GUISetState()
; Добавляет стандартный системный bitmaps
Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
Case 0
_GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
Case 2
_GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
EndSwitch
; Добавляет кнопки
_GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW)
_GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN)
_GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE)
_GUICtrlToolbar_AddButtonSep($hToolbar)
_GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)
; Показывает состояние кнопки "Save"
MemoWrite('Состояние кнопки "Save": ' & _GUICtrlToolbar_GetButtonState($hToolbar, $idSave))
Sleep(1000)
; Устанавливает состояние кнопки "Save"
Local $bool = _GUICtrlToolbar_SetButtonState($hToolbar, $idSave, BitOR($TBSTATE_ENABLED, $TBSTATE_PRESSED))
MemoWrite('Устанавливает состояние кнопки "Save": ' & $bool)
; Показывает состояние кнопки "Save"
MemoWrite('Состояние кнопки "Save": ' & _GUICtrlToolbar_GetButtonState($hToolbar, $idSave))
; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main
; Записывает строку в элемент для заметок
Func MemoWrite($sMessage = "")
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite