↑  ←  Описание функции

_GUICtrlToolbar_SetButtonInfo

Устанавливает информацию кнопки

#include <GuiToolBar.au3>
_GUICtrlToolbar_SetButtonInfo($hWnd, $iCommandID [, $iImage = -3 [, $iState = -1 [, $iStyle = -1 [, $iWidth = -1 [, $iParam = -1]]]]])

Параметры

$hWnd Дескриптор элемента
$iCommandID Идентификатор кнопки
$iImage [необязательный] Индекс изображения кнопки, отсчёт от 0. Установите параметр равным -1 и элемент будет высылать уведомление $TBN_GETDISPINFO, чтобы получить индекс изображения, когда это необходимо. Установите параметр равным -2, чтобы указать, что кнопка не имеет изображения. Компоновка кнопки будет включать только место для текста. Если кнопка является разделителем, то изображение определяет ширину разделителя в пикселях.
$iState [необязательный] Состояния кнопки. Это может быть комбинацией следующих значений:
    $TBSTATE_CHECKED - Кнопка имеет стиль $TBSTYLE_CHECK и вид нажатой кнопки
    $TBSTATE_PRESSED - Нажатая кнопка
    $TBSTATE_ENABLED - Кнопка доступна
    $TBSTATE_HIDDEN - Кнопка скрыта
    $TBSTATE_INDETERMINATE - Кнопка серая
    $TBSTATE_WRAP - Кнопка сопровождается переносом на новую строку кнопок
    $TBSTATE_ELLIPSES - Текст кнопки обрезается и отображается многоточие
    $TBSTATE_MARKED - The button is marked
$iStyle [необязательный] Стиль кнопки. Это может быть комбинацией следующих значений:
    $BTNS_AUTOSIZE - Toolbar не должен назначать стандартную ширину кнопок
    $BTNS_BUTTON - Стандартная кнопка
    $BTNS_CHECK - Переключает между нажатым и отжатым положением
    $BTNS_CHECKGROUP - Кнопка остаётся нажатой до тех пор, пока не будет нажата иная кнопка в группе
    $BTNS_DROPDOWN - Создаёт кнопку со стилем раскрывающегося вниз списка
    $BTNS_GROUP - Кнопка остаётся нажатой до тех пор, пока не будет нажата иная кнопка в группе
    $BTNS_NOPREFIX - Текст кнопки не будет иметь префикс быстрой клавиши
    $BTNS_SEP - Создаёт разделитель
    $BTNS_SHOWTEXT - Указывает, что текст кнопки должен отображаться
    $BTNS_WHOLEDROPDOWN - Указывает, что кнопка будет иметь стрелку раскрывающегося списка
$iWidth [необязательный] Ширина кнопки
$iParam [необязательный] Ассоциативное значение кнопки

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

См. также

_GUICtrlToolbar_GetButtonInfo, $tagTBBUTTONINFO

Пример

#include <GuiToolbar.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

$Debug_TB = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает
Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $hToolbar, $aButton
    Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp

    ; Создаёт GUI
    $hGUI = GUICreate(StringTrimRight(@ScriptName, 4), 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    $iMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 10, 400, 0, "Courier New")
    GUISetState()

    ; Добавляет стандартный системный bitmaps
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; Добавляет кнопки
    _GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; Устанавливает информацию кнопки "Save"
    _GUICtrlToolbar_SetButtonInfo($hToolbar, $idSave, $STD_PRINT, BitOR($TBSTATE_PRESSED, $TBSTATE_ENABLED), -1, 100, 1234)

    ; Показывает информацию кнопки "Save"
    $aButton = _GUICtrlToolbar_GetButtonInfo($hToolbar, $idSave)
    MemoWrite("Индекс изображения: " & $aButton[0])
    MemoWrite("Флаги состояния ..: " & $aButton[1])
    MemoWrite("Флаги стиля ......: " & $aButton[2])
    MemoWrite("Ширина кнопки ....: " & $aButton[3])
    MemoWrite("Ассоциат. значение: " & $aButton[4])

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite