↑  ←  Описание функции

_GUICtrlToolbar_HideButton

Скрывает или показывает указанную кнопку

#include <GuiToolBar.au3>
_GUICtrlToolbar_HideButton($hWnd, $iCommandID [, $fHide = True])

Параметры

$hWnd Дескриптор элемента
$iCommandID Идентификатор кнопки
$fHide [необязательный] Устанавливаемое состояние:
    True - Кнопка будет скрыта
    False - Кнопка будет показана

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

См. также

_GUICtrlToolbar_EnableButton

Пример

#include <GuiToolbar.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

$Debug_TB = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hGUI, $hToolbar, $aStrings[4]
    Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp

    ; Создаёт GUI
    $hGUI = GUICreate(StringTrimRight(@ScriptName, 4), 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    GUISetState()

    ; Добавляет стандартный системный bitmaps
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; Добавляет строки
    $aStrings[0] = _GUICtrlToolbar_AddString($hToolbar, "&Новая")
    $aStrings[1] = _GUICtrlToolbar_AddString($hToolbar, "&Открыть")
    $aStrings[2] = _GUICtrlToolbar_AddString($hToolbar, "&Сохранить")
    $aStrings[3] = _GUICtrlToolbar_AddString($hToolbar, "&Справка")

    ; Добавляет кнопки
    _GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW, $aStrings[0])
    _GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN, $aStrings[1])
    _GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE, $aStrings[2])
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP, $aStrings[3])

    ; Скрывает кнопку "Сохранить"
    MsgBox(4096, "Информация", 'Скрывает кнопку "Сохранить"')
    _GUICtrlToolbar_HideButton($hToolbar, $idSave, True)
    MsgBox(4096, "Информация", 'Показывает кнопку "Сохранить"')
    _GUICtrlToolbar_HideButton($hToolbar, $idSave, False)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main