Функция _GUICtrlToolbar

_GUICtrlToolbar_GetExtendedStyle

Возвращает расширенные стили

#include <GuiToolBar.au3>
_GUICtrlToolbar_GetExtendedStyle($hWnd)

Параметры

$hWnd

Дескриптор элемента

Возвращаемое значение

Успех: Возвращает расширенные стили Toolbar. Это может быть комбинацией следующих значений:
        $TBSTYLE_EX_DRAWDDARROWS - Позволяет кнопкам иметь отдельную стрелку вниз для выпадающего вниз меню.
        $TBSTYLE_EX_MIXEDBUTTONS - Позволяет соединять текст кнопки с изображением
        $TBSTYLE_EX_HIDECLIPPEDBUTTONS - Скрывает частично подрезанные кнопки
        $TBSTYLE_EX_DOUBLEBUFFER - Задаёт двойную буферизацию для Toolbar

См. также

_GUICtrlToolbar_SetExtendedStyle

Пример

#include <GuiToolbar.au3>
#include <GuiMenu.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

$Debug_TB = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает
Global $hGUI, $iMemo

_Main()

Func _Main()
Local $hToolbar
Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp

; Создаёт GUI
$hGUI = GUICreate(StringTrimRight(@ScriptName, 4), 400, 300)
$hToolbar = _GUICtrlToolbar_Create($hGUI)
_GUICtrlToolbar_SetExtendedStyle($hToolbar, $TBSTYLE_EX_DRAWDDARROWS)
$iMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
GUICtrlSetFont($iMemo, 10, 400, 0, "Courier New")
GUISetState()

; Добавляет стандартный системный bitmaps
Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
Case 0
_GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
Case 2
_GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
EndSwitch

; Добавляет кнопки
_GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW, 0, $BTNS_DROPDOWN)
_GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN)
_GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE)
_GUICtrlToolbar_AddButtonSep($hToolbar)
_GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

; Показывает используемые расширенные стили
MemoWrite("Расширенные стили: " & _GUICtrlToolbar_GetExtendedStyle($hToolbar))
GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage = "")
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite

; Обработка уведомлений TBN_DROPDOWN
Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
#forceref $hWnd, $iMsg, $iwParam
Local $tNMHDR, $iCode, $hMenu

$tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
$iCode = DllStructGetData($tNMHDR, "Code")

If $iCode = $TBN_DROPDOWN Then
$hMenu = _GUICtrlMenu_CreatePopup()
_GUICtrlMenu_AddMenuItem($hMenu, "Шаблон 1", 2000)
_GUICtrlMenu_AddMenuItem($hMenu, "Шаблон 2", 2001)
_GUICtrlMenu_AddMenuItem($hMenu, "Шаблон 3", 2002)
_GUICtrlMenu_TrackPopupMenu($hMenu, $hGUI)
_GUICtrlMenu_DestroyMenu($hMenu)
EndIf
Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY