↑  ←  Описание функции

_GUICtrlToolbar_GetColorScheme

Возвращает цветовую схему

#include <GuiToolBar.au3>
_GUICtrlToolbar_GetColorScheme($hWnd)

Параметры

$hWnd Дескриптор элемента

Возвращаемое значение

Успех: Возвращает массив следующего формата:
        [0] - Цвет подсвеченной стороны кнопки
        [1] - Цвет затемнённой стороны кнопки

Примечания

Элемент управления использует цветовую схему при отображении трехмерного состояния элементов и если используется классический стиль.

См. также

_GUICtrlToolbar_SetColorScheme

Пример

#include <GuiToolbar.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

$Debug_TB = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает
Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $hToolbar, $aScheme
    Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp

    ; Создаёт GUI
    $hGUI = GUICreate(StringTrimRight(@ScriptName, 4), 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    $iMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 10, 400, 0, "Courier New")
    GUISetState()

    ; Добавляет стандартный системный bitmaps
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; Добавляет кнопки
    _GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; Устанавливает классический стиль, чтобы увидеть изменения схемы
    DllCall("UxTheme.dll", "int", "SetWindowTheme", "hwnd", $hToolbar, "wstr", 0, "wstr", 0)

    ; Изменяет цветовую схему
    _GUICtrlToolbar_SetColorScheme($hToolbar, 0xff0000, 0x0000ff)

    ; Показывает цветовую схему
    $aScheme = _GUICtrlToolbar_GetColorScheme($hToolbar)
    MemoWrite("Подсвеченная сторона: " & '0x' & Hex($aScheme[0], 6))
    MemoWrite("Затемнённая сторона : " & '0x' & Hex($aScheme[1], 6))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite