↑  ←  Описание функции

_GUICtrlToolbar_GetButtonRect

Возвращает ограничивающий прямоугольник кнопки

#include <GuiToolBar.au3>
_GUICtrlToolbar_GetButtonRect($hWnd, $iCommandID)

Параметры

$hWnd Дескриптор элемента
$iCommandID Идентификатор кнопки

Возвращаемое значение

Успех: Возвращает массив следующего формата:
        [0] - X-координата левого верхнего угла прямоугольника
        [1] - Y-координата левого верхнего угла прямоугольника
        [2] - X-координата правого нижнего угла прямоугольника
        [3] - Y-координата правого нижнего угла прямоугольника

См. также

_GUICtrlToolbar_GetButtonRectEx

Пример

#include <GuiToolbar.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

$Debug_TB = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает
Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $hToolbar, $aRect
    Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp

    ; Создаёт GUI
    $hGUI = GUICreate(StringTrimRight(@ScriptName, 4), 400, 300)
    $hToolbar = _GUICtrlToolbar_Create ($hGUI)
    $iMemo = GUICtrlCreateEdit("", 2, 36, 396, 262, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 10, 400, 0, "Courier New")
    GUISetState()

    ; Добавляет стандартный системный bitmaps
    Switch _GUICtrlToolbar_GetBitmapFlags ($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap ($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap ($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; Добавляет кнопки
    _GUICtrlToolbar_AddButton ($hToolbar, $idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton ($hToolbar, $idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton ($hToolbar, $idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep ($hToolbar)
    _GUICtrlToolbar_AddButton ($hToolbar, $idHelp, $STD_HELP)

    ; Показывает прямоугольник кнопки "Save"
    $aRect = _GUICtrlToolbar_GetButtonRect ($hToolbar, $idSave)
    MemoWrite('Стороны прямоугольника кнопки "Save" ')
    MemoWrite("----------------")
    MemoWrite("Левая  : " & $aRect[0])
    MemoWrite("Верхняя: " & $aRect[1])
    MemoWrite("Правая : " & $aRect[2])
    MemoWrite("Нижняя : " & $aRect[3])

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite