_GUICtrlTab_SetItemImage
Устанавливает изображение вкладке
#include <GuiTab.au3>
_GUICtrlTab_SetItemImage($hWnd, $iIndex, $iImage)
Параметры
| $hWnd | Дескриптор или идентификатор элемента |
| $iIndex |
Индекс вкладки, отсчёт от 0 |
| $iImage |
Индекс изображения, отсчёт от 0 |
Возвращаемое значение
| Успех: | Возвращает True |
| Ошибка: | Возвращает False |
См. также
_GUICtrlTab_GetItemImageПример
#include <GUIConstantsEx.au3>
#include <GuiTab.au3>
#include <GuiImageList.au3>
$Debug_TAB = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает
_Main()
Func _Main()
Local $hGUI, $hImage, $hTab
; Создаёт GUI
$hGUI = GUICreate("Получает изображение вкладки", 400, 300)
$hTab = GUICtrlCreateTab(2, 2, 396, 296)
GUISetState()
; Создаёт изображения
$hImage = _GUIImageList_Create()
_GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0xFF0000, 16, 16))
_GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x00FF00, 16, 16))
_GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x0000FF, 16, 16))
_GUICtrlTab_SetImageList($hTab, $hImage)
; Вставляет вкладки
_GUICtrlTab_InsertItem($hTab, 0, "Вкладка 1")
_GUICtrlTab_InsertItem($hTab, 1, "Вкладка 2")
_GUICtrlTab_InsertItem($hTab, 2, "Вкладка 3")
; Установить / получить изображение вкладки
_GUICtrlTab_SetItemImage($hTab, 1, 1)
MsgBox(4160, "Информация", "Индекс изображения вкладки 2: " & _GUICtrlTab_GetItemImage($hTab, 1))
; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main