Функция _GUICtrlTab

_GUICtrlTab_RemoveImage

Удаляет изображение из списка изображений

#include <GuiTab.au3>
_GUICtrlTab_RemoveImage($hWnd, $iIndex)

Параметры

$hWnd	Дескриптор или идентификатор элемента
$iIndex	Индекс удаляемого изображения, отсчёт от 0

Примечания

Элемент Tab обновляет индексы изображений у каждой вкладки таким образом, что каждая вкладка продолжает оставаться связанной с тем же изображением как и раньше.
Если вкладка использует удаляемое изображение, то она будет установлена как вкладка без изображения.

Пример

#include <GUIConstantsEx.au3>
#include <GuiTab.au3>
#include <WinAPI.au3>
#include <GuiImageList.au3>

$Debug_TAB = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
Local $hGUI, $hImage, $hTab

; Создаёт GUI
$hGUI = GUICreate("Удаляет изображение", 400, 300)
$hTab = GUICtrlCreateTab(2, 2, 396, 296)
GUISetState()

; Создаёт изображения
$hImage = _GUIImageList_Create()
_GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0xFF0000, 16, 16))
_GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x00FF00, 16, 16))
_GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x0000FF, 16, 16))
_GUICtrlTab_SetImageList($hTab, $hImage)

; Вставляет вкладки
_GUICtrlTab_InsertItem($hTab, 0, "Вкладка 1", 0)
_GUICtrlTab_InsertItem($hTab, 1, "Вкладка 2", 1)
_GUICtrlTab_InsertItem($hTab, 2, "Вкладка 3", 2)

; Удаляет второе изображение
MsgBox(4160, "Информация", _
"Удаляет второе изображение в списке" & @LF & _
"Количество изображений на данный момент : " & _GUIImageList_GetImageCount($hImage))
_GUICtrlTab_RemoveImage($hTab, 1)
MsgBox(4160, "Информация", _
"Удалено." & @LF & _
"Количество изображений на данный момент : " & _GUIImageList_GetImageCount($hImage))

; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main