_GUICtrlRichEdit_GetParaTabStops
Gets the tabstops of (first) selected paragraph or (if no selection) of the current paragraph
#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetParaTabStops($hWnd)
Параметры
| $hWnd | Дескриптор элемента |
Возвращаемое значение
| Успех: | A string consisting of values separated by ; (semicolons). |
| value 1 - number of tabstops | |
| values 2 to | |
| absolute position of a tab stop (in space units) | |
| kind of tab | |
| l - left tab | |
| c - center tab | |
| r - decimal tab | |
| b - bar tab (a vertical bar, as in Word) | |
| kind of dot leader | |
| . - dotted leader | |
| - - dashed leader | |
| _ - underline leader | |
| = - double line leader | |
| t - thick-line leader | |
| a space - no leader | |
| Value | |
| a - all (or only) selected paragraphs have these settings | |
| f - the first selected paragraph has these settings, but other(s) don't | |
| c - the current paragraph has these settings | |
| Ошибка: | Возвращает "" - пустую строку и устанавливает @error |
| @error: | 101 - $hWnd is not a handle |
Примечания
To enter a tab into a control, press Ctrl_TabСм. также
_GUICtrlRichEdit_SetParaTabStopsСм. также
Искать EM_GETPARAFORMAT в библиотеке MSDNПример
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Global $lblMsg, $hRichEdit
Main()
Func Main()
Local $hGui, $btnNext, $iStep = 0
$hGui = GUICreate(StringTrimRight(@ScriptName, 4), 420, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, 'Это тест.', 10, 10, 400, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$btnNext = GUICtrlCreateButton("Далее", 270, 310, 60, 30)
GUISetState()
_GUICtrlRichEdit_SetText($hRichEdit, "First paragraph")
Report("0. Para with default settings")
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
_GUICtrlRichEdit_Destroy($hRichEdit)
GUIDelete()
Exit
Case $btnNext
$iStep += 1
Switch $iStep
Case 1
_GUICtrlRichEdit_AppendText($hRichEdit, @CR & "Second paragraph")
_GUICtrlRichEdit_SetParaTabStops($hRichEdit, ".3l ;1c ;2.5r.")
Report("1. TabStops of second paragraph")
Case 2
_GUICtrlRichEdit_SetSel($hRichEdit, 0, 2)
Report("2. Tabstops of first paragraph")
Case 3
_GUICtrlRichEdit_SetSel($hRichEdit, 10, 26)
Report("Tabstops of first paragraph in selection")
Case 4
_GUICtrlRichEdit_SetParaTabStops($hRichEdit, "2.3r=")
Report("3. Change tabstops of both paragraphs")
Case 5
; Весь RTF-код сохраняет в файл на Рабочем столе чтобы посмотреть в Word
_GUICtrlRichEdit_Deselect($hRichEdit)
_GUICtrlRichEdit_StreamToFile($hRichEdit, @DesktopDir & "\gcre.rtf")
GUICtrlSetState($btnNext, $GUI_DISABLE)
EndSwitch
EndSwitch
WEnd
EndFunc ;==>Main
Func Report($sMsg)
$sMsg &= @cr & @cr & "get function returns " & @cr & _GUICtrlRichEdit_GetParaTabStops($hRichEdit)
GUICtrlSetData($lblMsg, $sMsg)
ControlFocus($hRichEdit, "", "")
EndFunc ;==>Report