_GUICtrlRichEdit_GetParaAlignment
Gets the alignment of selected paragraph(s), or (if no selection) of the current paragraph
#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetParaAlignment($hWnd)
Параметры
| $hWnd | Дескриптор элемента |
Возвращаемое значение
| Успех: | a string consisting of a value, a semicolon (;), and a scope character: |
| alignment: | |
| l - aligned with the left margin. | |
| r - aligned with the right margin. | |
| c - centered between margins | |
| j - justified between margins | |
| f - justified between margins | |
| w - justified between margins by only expanding spaces | |
| scope: | |
| a - all (or only) selected paragraphs have this alignment | |
| f - the first selected paragraph has this alignment, but other(s) don't | |
| c - the current paragraph has this alignment | |
| Ошибка: | Возвращает "" - пустую строку и устанавливает @error |
| @error: | 101 - $hWnd is not a handle |
Примечания
In Richedit 2.0, justify does not displayСм. также
_GUICtrlRichEdit_SetParaAlignmentСм. также
Искать EM_SETPARAFORMAT в библиотеке MSDNПример
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Global $lblMsg, $hRichEdit
Main()
Func Main()
Local $hGui, $iCp, $btnNext, $iStep = 0
$hGui = GUICreate(StringTrimRight(@ScriptName, 4), 420, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, 'Это тест.', 10, 10, 400, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$btnNext = GUICtrlCreateButton("Далее", 270, 310, 60, 30)
GUISetState()
_GUICtrlRichEdit_SetText($hRichEdit, "First paragraph")
Report("First paragraph")
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
_GUICtrlRichEdit_Destroy($hRichEdit)
GUIDelete()
Exit
Case $btnNext
$iStep += 1
Switch $iStep
Case 1
_GUICtrlRichEdit_SetParaAlignment($hRichEdit, "r")
Report("First paragraph")
Case 2
_GUICtrlRichEdit_AppendText($hRichEdit, @CR & "Second paragraph")
_GUICtrlRichEdit_SetParaAlignment($hRichEdit, "c")
Report("Second paragraph")
Case 3
_GUICtrlRichEdit_AppendText($hRichEdit, @CR & "Third paragraph")
_GUICtrlRichEdit_SetParaAlignment($hRichEdit, "l")
Report("Third paragraph")
Case 4
$iCp = _GUICtrlRichEdit_GetFirstCharPosOnLine($hRichEdit, 2)
_GUICtrlRichEdit_SetSel($hRichEdit, $iCp, -1)
Report("Alignment of paragraphs in selection")
GUICtrlSetState($btnNext, $GUI_DISABLE)
EndSwitch
EndSwitch
WEnd
EndFunc ;==>Main
Func Report($sMsg)
$sMsg &= @cr & @cr & "get function returns " & @cr & _GUICtrlRichEdit_GetParaAlignment($hRichEdit)
GUICtrlSetData($lblMsg, $sMsg)
ControlFocus($hRichEdit, "", "")
EndFunc ;==>Report