↑  ←  Описание функции

_GUICtrlRichEdit_GetBkColor

Возвращает цвет фона элемента

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetBkColor($hWnd)

Параметры

$hWnd Дескриптор элемента

Возвращаемое значение

Успех:Возвращает цвет COLORREF
Ошибка:устанавливает @error
@error:101 - $HWnd не является дескриптором

Примечания

Если вам нужно создать массив значений цвета, то используйте _ColorGetCOLORREF(), а не _ColorGetRGB().

См. также

_GUICtrlRichEdit_SetBkColor

См. также

Искать EM_SETBKGNDCOLOR в библиотеке MSDN

Пример

#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Color.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $btnNext, $iStep = 0
    $hGui = GUICreate(StringTrimRight(@ScriptName, 4), 420, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "", 10, 10, 400, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Далее", 270, 310, 60, 30)
    GUISetState()

    _GUICtrlRichEdit_SetText($hRichEdit, 'Это тест.')
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit)
                GUIDelete()
                Exit
            Case $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_SetBkColor($hRichEdit, 0xE8CCCC)
                        Report("1. Цветной фон")
                    Case 2
                        _GUICtrlRichEdit_SetBkColor($hRichEdit)
                        Report("2. Восстановление белого фона")
                    Case 3
                        _GUICtrlRichEdit_SetBkColor($hRichEdit, 0xB3B3C7)
                        Report("3. Цветной фон снова")
                        ; Весь RTF-код сохраняет в файл на Рабочем столе чтобы посмотреть в Word
                        _GUICtrlRichEdit_StreamToFile($hRichEdit, @DesktopDir & "\gcre.rtf")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSwitch
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    Local $iBngColor = _GUICtrlRichEdit_GetBkColor($hRichEdit)
    Local $aRet = _ColorGetRGB($iBngColor)
    $sMsg &=  @cr & @cr & $aret[0] & ";" & $aret[1] & ";" & $aret[2] & "    цвет фона=0x" & Hex($iBngColor)
    GUICtrlSetData($lblMsg, $sMsg)
    ControlFocus($hRichEdit, "", "")
EndFunc   ;==>Report