_GUICtrlMenu_SetItemBmpChecked
Устанавливает bitmap, отображаемый возле пункта, когда он отмеченный
#include <GuiMenu.au3>
_GUICtrlMenu_SetItemBmpChecked($hMenu, $iItem, $hBmp [, $fByPos = True])
Параметры
| $hMenu | Дескриптор меню |
| $iItem |
Идентификатор или позиция пункта меню |
| $hBmp |
Дескриптор bitmap, отображаемый возле пункта, когда он отмеченный |
| $fByPos |
[необязательный] Флаг для идентификации меню: True - $iItem является позицией пункта, отсчёт от 0 False - $iItem является идентификатором пункта |
Возвращаемое значение
| Успех: | Возвращает True |
| Ошибка: | Возвращает False |
См. также
_GUICtrlMenu_GetItemBmpChecked, _GUICtrlMenu_SetItemBitmapsПример
#include <GuiMenu.au3>
#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
Global $iMemo
_Main()
Func _Main()
Local $hGUI, $hFile, $hEdit, $hHelp, $hMain, $hBmp1, $hBmp2
Local Enum $idNew = 1000, $idOpen, $idSave, $idExit, $idCut, $idCopy, $idPaste, $idAbout
; Создаёт GUI
$hGUI = GUICreate("Устанавливает bitmap состояния", 400, 300)
; Создаёт меню "Файл"
$hFile = _GUICtrlMenu_CreateMenu ()
_GUICtrlMenu_InsertMenuItem ($hFile, 0, 'Новый', $idNew)
_GUICtrlMenu_InsertMenuItem ($hFile, 1, 'Открыть', $idOpen)
_GUICtrlMenu_InsertMenuItem ($hFile, 2, 'Сохранить', $idSave)
_GUICtrlMenu_InsertMenuItem ($hFile, 3, "", 0)
_GUICtrlMenu_InsertMenuItem ($hFile, 4, 'Выход', $idExit)
; Создаёт меню "Правка"
$hEdit = _GUICtrlMenu_CreateMenu ()
_GUICtrlMenu_InsertMenuItem ($hEdit, 0, 'Вырезать', $idCut)
_GUICtrlMenu_InsertMenuItem ($hEdit, 1, 'Копировать', $idCopy)
_GUICtrlMenu_InsertMenuItem ($hEdit, 2, 'Вставить', $idPaste)
; Создаёт меню "Справка"
$hHelp = _GUICtrlMenu_CreateMenu ()
_GUICtrlMenu_InsertMenuItem ($hHelp, 0, 'О программе', $idAbout)
; Создаёт главное меню
$hMain = _GUICtrlMenu_CreateMenu ()
_GUICtrlMenu_InsertMenuItem ($hMain, 0, 'Файл', 0, $hFile)
_GUICtrlMenu_InsertMenuItem ($hMain, 1, 'Правка', 0, $hEdit)
_GUICtrlMenu_InsertMenuItem ($hMain, 2, 'Справка', 0, $hHelp)
; Устанавливает главное меню окна
_GUICtrlMenu_SetMenu ($hGUI, $hMain)
; Создаёт элемент для заметок
$iMemo = GUICtrlCreateEdit("", 2, 2, 396, 276, 0)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState()
; Устанавливает в меню "Файл" состояние пунктов с помощью bitmap
$hBmp1 = _WinAPI_CreateSolidBitmap ($hGUI, 0xFF0000, 11, 11)
$hBmp2 = _WinAPI_CreateSolidBitmap ($hGUI, 0x00FF00, 11, 11)
_GUICtrlMenu_SetItemBmpChecked ($hFile, 0, $hBmp1)
_GUICtrlMenu_SetItemBmpChecked ($hFile, 1, $hBmp1)
_GUICtrlMenu_SetItemBmpChecked ($hFile, 2, $hBmp1)
_GUICtrlMenu_SetItemBmpUnChecked ($hFile, 0, $hBmp2)
_GUICtrlMenu_SetItemBmpUnChecked ($hFile, 1, $hBmp2)
_GUICtrlMenu_SetItemBmpUnChecked ($hFile, 2, $hBmp2)
; Ставит галочку на пункт меню "Открыть"
_GUICtrlMenu_CheckMenuItem ($hFile, 1)
; Показывает, что дескрипторы bitmap соответствуют
MemoWrite("Дескриптор bitmap с галочкой ...: 0x" & Hex($hBmp1))
MemoWrite("Дескриптор bitmap без галочки ..: 0x" & Hex($hBmp2))
MemoWrite("Дескриптор с галочкой на пункте : 0x" & Hex(_GUICtrlMenu_GetItemBmpChecked ($hFile, 0)))
MemoWrite("Дескриптор без галочки на пункте: 0x" & Hex(_GUICtrlMenu_GetItemBmpUnchecked ($hFile, 0)))
; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main
; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite