↑  ←  Описание функции

_GUICtrlMenu_CreateMenu

Создает меню

#include <GuiMenu.au3>
_GUICtrlMenu_CreateMenu([$iStyle = 8])

Параметры

$iStyle [необязательный] Стиль меню. Это может быть одним или комбинацией следующих значений:
    1 - Меню автоматически закрывается, если мышь находится вне меню более 10 секунд
    2 - Отводит место для галочки или bitmap
    4 - Пункты меню являются OLE целью бросания или перетаскиваемым источником
    8 - Немодальное меню
    16 - Не отводит место слева от пункта для галочки
    32 - Владелец меню получает сообщение WM_MENUCOMMAND вместо WM_COMMAND, когда делается выбор

Возвращаемое значение

Успех:Возвращает дескриптор созданного меню
Ошибка:Возвращает 0

Примечания

Ресурсы меню, которое назначено окну, высвобождаются автоматически. Если меню не назначено окну, то приложение должно освободить системные ресурсы, связанные с этим меню перед закрытием. Приложение освобождает ресурсы меню вызовом функции _GUICtrlMenu_DestroyMenu.

См. также

_GUICtrlMenu_CreatePopup, _GUICtrlMenu_DestroyMenu

См. также

Искать CreateMenu в библиотеке MSDN

Пример

#include <GuiMenu.au3>
#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>

Global $iMemo
Global Enum $idNew = 1000, $idOpen, $idSave, $idExit, $idCut, $idCopy, $idPaste, $idAbout

_Main()

Func _Main()
    Local $hGUI, $hFile, $hEdit, $hHelp, $hMain

    ; Создаёт GUI
    $hGUI = GUICreate("Создаёт меню", 400, 300)

    ; Создаёт меню "Файл"
    $hFile = _GUICtrlMenu_CreateMenu ()
    _GUICtrlMenu_InsertMenuItem ($hFile, 0, 'Новый', $idNew)
    _GUICtrlMenu_InsertMenuItem ($hFile, 1, 'Открыть', $idOpen)
    _GUICtrlMenu_InsertMenuItem ($hFile, 2, 'Сохранить', $idSave)
    _GUICtrlMenu_InsertMenuItem ($hFile, 3, "", 0)
    _GUICtrlMenu_InsertMenuItem ($hFile, 4, 'Выход', $idExit)

    ; Создаёт меню "Правка"
    $hEdit = _GUICtrlMenu_CreateMenu ()
    _GUICtrlMenu_InsertMenuItem ($hEdit, 0, 'Вырезать', $idCut)
    _GUICtrlMenu_InsertMenuItem ($hEdit, 1, 'Копировать', $idCopy)
    _GUICtrlMenu_InsertMenuItem ($hEdit, 2, 'Вставить', $idPaste)

    ; Создаёт меню "Справка"
    $hHelp = _GUICtrlMenu_CreateMenu ()
    _GUICtrlMenu_InsertMenuItem ($hHelp, 0, 'О программе', $idAbout)

    ; Создаёт главное меню
    $hMain = _GUICtrlMenu_CreateMenu ()
    _GUICtrlMenu_InsertMenuItem ($hMain, 0, 'Файл', 0, $hFile)
    _GUICtrlMenu_InsertMenuItem ($hMain, 1, 'Правка', 0, $hEdit)
    _GUICtrlMenu_InsertMenuItem ($hMain, 2, 'Справка', 0, $hHelp)

    ; Устанавливает главное меню окна
    _GUICtrlMenu_SetMenu ($hGUI, $hMain)

    ; Создаёт элемент для заметок
    $iMemo = GUICtrlCreateEdit("", 2, 2, 396, 276, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; Выполняется, пока окно не будет закрыто
    GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main

; Обработчик команд меню
Func WM_COMMAND($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $ilParam
    Switch _WinAPI_LoWord ($iwParam)
        Case $idNew
            MemoWrite("Новый")
        Case $idOpen
            MemoWrite("Открыть")
        Case $idSave
            MemoWrite("Сохранить")
        Case $idExit
            Exit
        Case $idCut
            MemoWrite("Вырезать")
        Case $idCopy
            MemoWrite("Копировать")
        Case $idPaste
            MemoWrite("Вставить")
        Case $idAbout
            MemoWrite("О программе")
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_COMMAND

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite