_GUICtrlMenu_FindItem
Поиск пункта меню на основе его текста
#include <GuiMenu.au3>
_GUICtrlMenu_FindItem($hMenu, $sText [, $fInStr = False [, $iStart = 0]])
Параметры
| $hMenu | Дескриптор меню |
| $sText |
Текст для поиска |
| $fInStr |
[необязательный] True означает, что искомый текст может находится в любом месте в тексте пункта. |
| $iStart |
[необязательный] Пункт, с которого начинать поиск |
Возвращаемое значение
| Успех: | Возвращает индекс первого пункта, содержащего указанный текст, отсчёт от 0 |
| Ошибка: | Возвращает -1 |
Примечания
Поиск не учитывает регистр буквПример
#include <GuiMenu.au3>
#include <GUIConstantsEx.au3>
_Main()
Func _Main()
Local $hGUI, $hFile, $hEdit, $hHelp, $hMain, $iIndex
Local Enum $idNew = 1000, $idOpen, $idSave, $idExit, $idCut, $idCopy, $idPaste, $idAbout
; Создаёт GUI
$hGUI = GUICreate("Поиск пункта", 400, 300)
GUISetState()
; Создаёт меню "Файл"
$hFile = _GUICtrlMenu_CreateMenu ()
_GUICtrlMenu_InsertMenuItem ($hFile, 0, 'Новый', $idNew)
_GUICtrlMenu_InsertMenuItem ($hFile, 1, 'Открыть', $idOpen)
_GUICtrlMenu_InsertMenuItem ($hFile, 2, 'Сохранить', $idSave)
_GUICtrlMenu_InsertMenuItem ($hFile, 3, "", 0)
_GUICtrlMenu_InsertMenuItem ($hFile, 4, 'Выход', $idExit)
; Создаёт меню "Правка"
$hEdit = _GUICtrlMenu_CreateMenu ()
_GUICtrlMenu_InsertMenuItem ($hEdit, 0, 'Вырезать', $idCut)
_GUICtrlMenu_InsertMenuItem ($hEdit, 1, 'Копировать', $idCopy)
_GUICtrlMenu_InsertMenuItem ($hEdit, 2, 'Вставить', $idPaste)
; Создаёт меню "Справка"
$hHelp = _GUICtrlMenu_CreateMenu ()
_GUICtrlMenu_InsertMenuItem ($hHelp, 0, 'О программе', $idAbout)
; Создаёт главное меню
$hMain = _GUICtrlMenu_CreateMenu ()
_GUICtrlMenu_InsertMenuItem ($hMain, 0, 'Файл', 0, $hFile)
_GUICtrlMenu_InsertMenuItem ($hMain, 1, 'Правка', 0, $hEdit)
_GUICtrlMenu_InsertMenuItem ($hMain, 2, 'Справка', 0, $hHelp)
; Устанавливает главное меню окна
_GUICtrlMenu_SetMenu ($hGUI, $hMain)
; Поиск пункта "Справка"
$iIndex = _GUICtrlMenu_FindItem ($hMain, 'Справка')
MsgBox(4096, "Информация", 'Индекс меню "Справка": ' & $iIndex)
; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main