↑  ←  Описание функции

_GUICtrlMenu_DrawMenuBar

Перерисовывает меню указанного окна

#include <GuiMenu.au3>
_GUICtrlMenu_DrawMenuBar($hWnd)

Параметры

$hWnd Дескриптор окна, меню которого нужно перерисовать

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

Примечания

Если главное меню изменено после создания окна, то эта функция должна быть вызвана, чтобы перерисовать главное меню.

См. также

Искать DrawMenuBar в библиотеке MSDN

Пример

#include <GuiMenu.au3>

_Main()

Func _Main()
    Local $hWnd, $hMain, $hItem1, $hItem2

    ; Запуск блокнота
    Run("notepad.exe")
    $hWnd = WinWaitActive("[CLASS:Notepad]")
    $hMain = _GUICtrlMenu_GetMenu($hWnd)

    ; Создаёт вложенные пункты меню
    $hItem1 = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hItem1, 0, "Подпункт &1", 0x1000)
    _GUICtrlMenu_InsertMenuItem($hItem1, 1, "Подпункт &2", 0x1001)

    ; Создаёт меню
    $hItem2 = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hItem2, 0, "Пункт &1", 0x2000, $hItem1)
    _GUICtrlMenu_InsertMenuItem($hItem2, 1, "Пункт &2", 0x2001)
    _GUICtrlMenu_InsertMenuItem($hItem2, 2, "", 0)
    _GUICtrlMenu_InsertMenuItem($hItem2, 3, "Пункт &3", 0x2002)
    _GUICtrlMenu_InsertMenuItem($hItem2, 4, "Пункт &4", 0x2003)

    ; Вставляет новое меню в Блокнот
    _GUICtrlMenu_InsertMenuItem($hMain, 6, 'Меню+', 0, $hItem2)
    _GUICtrlMenu_DrawMenuBar($hWnd)

EndFunc   ;==>_Main