↑  ←  Описание функции

_GUICtrlMenu_CheckRadioItem

Отмечает указанный элемент меню и делает его радиопунктом

#include <GuiMenu.au3>
_GUICtrlMenu_CheckRadioItem($hMenu, $iFirst, $iLast, $iCheck [, $fByPos = True])

Параметры

$hMenu Дескриптор меню
$iFirst Идентификатор или позиция первого пункта меню в группе
$iLast Идентификатор или позиция последнего пункта меню в группе
$iCheck Идентификатор или позиция пункта меню для установки кружка
$fByPos [необязательный] Флаг для идентификации меню:
    True - $iFirst, $iLast and $iCheck является позицией пункта, отсчёт от 0
    False - $iFirst, $iLast and $iCheck является идентификатором пункта

Возвращаемое значение

Успех:Возвращает True
Ошибка:Возвращает False

Примечания

Эта функция устанавливает тип флага $MFT_RADIOCHECK и состояние $MFS_CHECKED для пункта указанного в $iCheck и одновременно убирает эти флаги для других пунктов в группе. Отмеченный пункт отображается в виде кружочка, вместо галочки.

См. также

_GUICtrlMenu_CheckMenuItem

См. также

Искать CheckMenuRadioItem в библиотеке MSDN

Пример

#include <GuiMenu.au3>
#include <GUIConstantsEx.au3>

_Main()

Func _Main()
    Local $hGUI, $hFile, $hEdit, $hHelp, $hMain
    Local Enum $idNew = 1000, $idOpen, $idSave, $idExit, $idCut, $idCopy, $idPaste, $idAbout

    ; Создаёт GUI
    $hGUI = GUICreate("Радиопункт", 400, 300)

    ; Создаёт меню "Файл"
    $hFile = _GUICtrlMenu_CreateMenu ()
    _GUICtrlMenu_InsertMenuItem ($hFile, 0, 'Новый', $idNew)
    _GUICtrlMenu_InsertMenuItem ($hFile, 1, 'Открыть', $idOpen)
    _GUICtrlMenu_InsertMenuItem ($hFile, 2, 'Сохранить', $idSave)
    _GUICtrlMenu_InsertMenuItem ($hFile, 3, "", 0)
    _GUICtrlMenu_InsertMenuItem ($hFile, 4, 'Выход', $idExit)

    ; Создаёт меню "Правка"
    $hEdit = _GUICtrlMenu_CreateMenu ()
    _GUICtrlMenu_InsertMenuItem ($hEdit, 0, 'Вырезать', $idCut)
    _GUICtrlMenu_InsertMenuItem ($hEdit, 1, 'Копировать', $idCopy)
    _GUICtrlMenu_InsertMenuItem ($hEdit, 2, 'Вставить', $idPaste)

    ; Создаёт меню "Справка"
    $hHelp = _GUICtrlMenu_CreateMenu ()
    _GUICtrlMenu_InsertMenuItem ($hHelp, 0, 'О программе', $idAbout)

    ; Создаёт главное меню
    $hMain = _GUICtrlMenu_CreateMenu ()
    _GUICtrlMenu_InsertMenuItem ($hMain, 0, 'Файл', 0, $hFile)
    _GUICtrlMenu_InsertMenuItem ($hMain, 1, 'Правка', 0, $hEdit)
    _GUICtrlMenu_InsertMenuItem ($hMain, 2, 'Справка', 0, $hHelp)

    ; Устанавливает главное меню окна
    _GUICtrlMenu_SetMenu ($hGUI, $hMain)
    GUISetState()

    ; Устанавливает кружок на пункт меню "Сохранить"
    _GUICtrlMenu_CheckRadioItem ($hFile, 0, 4, 2)

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main