↑  ←  Описание функции

_GUICtrlListView_HitTest

Определяет, какой пункт находится в указанных координатах

#include <GuiListView.au3>
_GUICtrlListView_HitTest($hWnd [, $iX = -1 [, $iY = -1]])

Параметры

$hWnd Дескриптор или идентификатор элемента
$iX [необязательный] X-координата относительно клиентской области ListView или -1 для использования текущего положения курсора мыши
$iY [необязательный] Y-координата относительно клиентской области ListView или -1 для использования текущего положения курсора мыши

Возвращаемое значение

Успех:Возвращает массив следующего формата:
[0] - Индекс пункта в указанной позиции, или -1
[1] - True означает, что позиция в клиентской области ListView, но не на пункте
[2] - True означает, что позиция над иконкой пункта
[3] - True означает, что позиция над текстом пункта
[4] - True означает, что позиция над изображением состояния пункта
[5] - True означает, что позиция в любом месте над пунктом
[6] - True означает, что позиция выше клиентской области ListView
[7] - True означает, что позиция ниже клиентской области ListView
[8] - True означает, что позиция левее клиентской области ListView
[9] - True означает, что позиция правее клиентской области ListView
Ошибка:Устанавливает @error

См. также

_GUICtrlListView_SubItemHitTest

Пример

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiStatusBar.au3>
#include <GuiImageList.au3>
#include <WindowsConstants.au3>

$Debug_LV = False ; Проверяет ClassName передаваемый в ListView функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

Global $hListView, $StatusBar, $iIndex = -1

_Main()

Func _Main()
    Local $hImage, $GUI

    ; Создаёт GUI
    $GUI = GUICreate("ListView Hit Test", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    $hListView = GUICtrlGetHandle($hListView) ; получает дескриптор для использования в уведомляющих событиях WM_NOTIFY
    $StatusBar = _GUICtrlStatusBar_Create($GUI, -1, "")

    ; Устанавливает расширенный стиль
    _GUICtrlListView_SetExtendedListViewStyle($hListView, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_SUBITEMIMAGES))
    GUISetState()

    GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

    ; Загружает изображения
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x0000FF, 16, 16))
    _GUICtrlListView_SetImageList($hListView, $hImage, 1)

    ; Добавляет колонки
    _GUICtrlListView_AddColumn($hListView, "Колонка 1", 120)
    _GUICtrlListView_AddColumn($hListView, "Колонка 2", 120)
    _GUICtrlListView_AddColumn($hListView, "Колонка 3", 120)

    ; Добавляет пункты
    _GUICtrlListView_AddItem($hListView, "Стр 1: Кол 1", 0)
    _GUICtrlListView_AddSubItem($hListView, 0, "Стр 1: Кол 2", 1, 1)
    _GUICtrlListView_AddSubItem($hListView, 0, "Стр 1: Кол 3", 2, 2)
    _GUICtrlListView_AddItem($hListView, "Стр 2: Кол 1", 1)
    _GUICtrlListView_AddSubItem($hListView, 1, "Стр 2: Кол 2", 1, 2)
    _GUICtrlListView_AddItem($hListView, "Стр 3: Кол 1", 2)

    ; Цикл выполняется, пока окно не будет закрыто
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
        EndSwitch
    WEnd
    GUIDelete()
EndFunc   ;==>_Main

Func _ListView_Click()
    Local $aHit

    $aHit = _GUICtrlListView_HitTest($hListView)
    If ($aHit[0] <> -1) And ($aHit[0] <> $iIndex) Then
        _GUICtrlStatusBar_SetText($StatusBar, @tab & StringFormat("HitTest Пункт: %d", $aHit[0]))
        $iIndex = $aHit[0]
    EndIf
EndFunc   ;==>_ListView_Click

Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $iwParam
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndListView, $tInfo
    $hWndListView = $hListView
    If Not IsHWnd($hListView) Then $hWndListView = GUICtrlGetHandle($hListView)

    $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    Switch $hWndFrom
        Case $hWndListView
            Switch $iCode
                Case $LVN_COLUMNCLICK ; Клик на заголовке колонки
                    $tInfo = DllStructCreate($tagNMLISTVIEW, $ilParam)
                    _DebugPrint("$LVN_COLUMNCLICK" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode & @LF & _
                            "-->Item:" & @tab & DllStructGetData($tInfo, "Item") & @LF & _
                            "-->SubItem:" & @tab & DllStructGetData($tInfo, "SubItem") & @LF & _
                            "-->NewState:" & @tab & DllStructGetData($tInfo, "NewState") & @LF & _
                            "-->OldState:" & @tab & DllStructGetData($tInfo, "OldState") & @LF & _
                            "-->Changed:" & @tab & DllStructGetData($tInfo, "Changed") & @LF & _
                            "-->ActionX:" & @tab & DllStructGetData($tInfo, "ActionX") & @LF & _
                            "-->ActionY:" & @tab & DllStructGetData($tInfo, "ActionY") & @LF & _
                            "-->Param:" & @tab & DllStructGetData($tInfo, "Param"))
                    ; Нет возвращаемых значений
                Case $LVN_KEYDOWN ; Клавиша была нажата
                    $tInfo = DllStructCreate($tagNMLVKEYDOWN, $ilParam)
                    _DebugPrint("$LVN_KEYDOWN" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode & @LF & _
                            "-->VKey:" & @tab & DllStructGetData($tInfo, "VKey") & @LF & _
                            "-->Flags:" & @tab & DllStructGetData($tInfo, "Flags"))
                    ; Нет возвращаемых значений
                Case $NM_CLICK ; Высылается элементом ListView, когда пользователь кликает пункт левой кнопкой мыши
                    $tInfo = DllStructCreate($tagNMITEMACTIVATE, $ilParam)
                    _DebugPrint("$NM_CLICK" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode & @LF & _
                            "-->Index:" & @tab & DllStructGetData($tInfo, "Index") & @LF & _
                            "-->SubItem:" & @tab & DllStructGetData($tInfo, "SubItem") & @LF & _
                            "-->NewState:" & @tab & DllStructGetData($tInfo, "NewState") & @LF & _
                            "-->OldState:" & @tab & DllStructGetData($tInfo, "OldState") & @LF & _
                            "-->Changed:" & @tab & DllStructGetData($tInfo, "Changed") & @LF & _
                            "-->ActionX:" & @tab & DllStructGetData($tInfo, "ActionX") & @LF & _
                            "-->ActionY:" & @tab & DllStructGetData($tInfo, "ActionY") & @LF & _
                            "-->lParam:" & @tab & DllStructGetData($tInfo, "lParam") & @LF & _
                            "-->KeyFlags:" & @tab & DllStructGetData($tInfo, "KeyFlags"))
                    _ListView_Click()
                    ; Нет возвращаемых значений
                Case $NM_DBLCLK ; Высылается элементом ListView, когда пользователь делает двойной клик на пункте левой кнопкой мыши
                    $tInfo = DllStructCreate($tagNMITEMACTIVATE, $ilParam)
                    _DebugPrint("$NM_DBLCLK" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode & @LF & _
                            "-->Index:" & @tab & DllStructGetData($tInfo, "Index") & @LF & _
                            "-->SubItem:" & @tab & DllStructGetData($tInfo, "SubItem") & @LF & _
                            "-->NewState:" & @tab & DllStructGetData($tInfo, "NewState") & @LF & _
                            "-->OldState:" & @tab & DllStructGetData($tInfo, "OldState") & @LF & _
                            "-->Changed:" & @tab & DllStructGetData($tInfo, "Changed") & @LF & _
                            "-->ActionX:" & @tab & DllStructGetData($tInfo, "ActionX") & @LF & _
                            "-->ActionY:" & @tab & DllStructGetData($tInfo, "ActionY") & @LF & _
                            "-->lParam:" & @tab & DllStructGetData($tInfo, "lParam") & @LF & _
                            "-->KeyFlags:" & @tab & DllStructGetData($tInfo, "KeyFlags"))
                    ; Нет возвращаемых значений
                Case $NM_KILLFOCUS ; Элемент потерял фокус ввода
                    _DebugPrint("$NM_KILLFOCUS" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
                    ; Нет возвращаемых значений
                Case $NM_RCLICK ; Высылается элементом ListView, когда пользователь кликает пункт правой кнопкой мыши
                    $tInfo = DllStructCreate($tagNMITEMACTIVATE, $ilParam)
                    _DebugPrint("$NM_RCLICK" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode & @LF & _
                            "-->Index:" & @tab & DllStructGetData($tInfo, "Index") & @LF & _
                            "-->SubItem:" & @tab & DllStructGetData($tInfo, "SubItem") & @LF & _
                            "-->NewState:" & @tab & DllStructGetData($tInfo, "NewState") & @LF & _
                            "-->OldState:" & @tab & DllStructGetData($tInfo, "OldState") & @LF & _
                            "-->Changed:" & @tab & DllStructGetData($tInfo, "Changed") & @LF & _
                            "-->ActionX:" & @tab & DllStructGetData($tInfo, "ActionX") & @LF & _
                            "-->ActionY:" & @tab & DllStructGetData($tInfo, "ActionY") & @LF & _
                            "-->lParam:" & @tab & DllStructGetData($tInfo, "lParam") & @LF & _
                            "-->KeyFlags:" & @tab & DllStructGetData($tInfo, "KeyFlags"))
                    ;Return 1 ; не разрешает обработку по умолчанию
                    Return 0 ; разрешает обработку по умолчанию
                Case $NM_RDBLCLK ; Высылается элементом ListView, когда пользователь делает двойной клик на пункте правой кнопкой мыши
                    $tInfo = DllStructCreate($tagNMITEMACTIVATE, $ilParam)
                    _DebugPrint("$NM_RDBLCLK" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode & @LF & _
                            "-->Index:" & @tab & DllStructGetData($tInfo, "Index") & @LF & _
                            "-->SubItem:" & @tab & DllStructGetData($tInfo, "SubItem") & @LF & _
                            "-->NewState:" & @tab & DllStructGetData($tInfo, "NewState") & @LF & _
                            "-->OldState:" & @tab & DllStructGetData($tInfo, "OldState") & @LF & _
                            "-->Changed:" & @tab & DllStructGetData($tInfo, "Changed") & @LF & _
                            "-->ActionX:" & @tab & DllStructGetData($tInfo, "ActionX") & @LF & _
                            "-->ActionY:" & @tab & DllStructGetData($tInfo, "ActionY") & @LF & _
                            "-->lParam:" & @tab & DllStructGetData($tInfo, "lParam") & @LF & _
                            "-->KeyFlags:" & @tab & DllStructGetData($tInfo, "KeyFlags"))
                    ; Нет возвращаемых значений
                Case $NM_RETURN ; Элемент имеет фокус ввода и пользователь нажал клавишу ENTER
                    _DebugPrint("$NM_RETURN" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
                    ; Нет возвращаемых значений
                Case $NM_SETFOCUS ; Элемент получил фокус ввода
                    _DebugPrint("$NM_SETFOCUS" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
                    ; Нет возвращаемых значений
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

Func _DebugPrint($s_text, $line = @ScriptLineNumber)
    ConsoleWrite( _
            "!===========================================================" & @LF & _
            "+======================================================" & @LF & _
            "-->Строка(" & StringFormat("%04d", $line) & "):" & @TAB & $s_text & @LF & _
            "+======================================================" & @LF)
EndFunc   ;==>_DebugPrint