↑  ←  Описание функции

_GUICtrlListView_GetOrigin

Возвращает текущие координаты начала в ListView

#include <GuiListView.au3>
_GUICtrlListView_GetOrigin($hWnd)

Параметры

$hWnd Дескриптор или идентификатор элемента

Возвращаемое значение

Возвращает массив следующего формата:
        [0] - X-координата
        [1] - Y-координата

См. также

_GUICtrlListView_GetOriginX, _GUICtrlListView_GetOriginY

Пример

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>

$Debug_LV = False ; Проверяет ClassName передаваемый в ListView функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $aOrigin, $hImage, $hListView

    GUICreate("Получает начало ListView", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUICtrlSetStyle($hListView, $LVS_ICON)
    GUISetState()

    ; Загружает изображения
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x0000FF, 16, 16))
    _GUICtrlListView_SetImageList($hListView, $hImage, 0)

    ; Добавляет колонки
    _GUICtrlListView_AddColumn($hListView, "Пункты", 100)

    ; Добавляет пункты
    _GUICtrlListView_AddItem($hListView, "Пункт 1", 0)
    _GUICtrlListView_AddItem($hListView, "Пункт 2", 1)
    _GUICtrlListView_AddItem($hListView, "Пункт 3", 2)

    ; Получает начало ListView
    $aOrigin = _GUICtrlListView_GetOrigin($hListView)
    MsgBox(4160, "Информация", StringFormat("Успешно: %s, Начало: X=%d, Y=%d", @extended = 1, $aOrigin[0], $aOrigin[1]))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main