↑  ←  Описание функции

_GUICtrlListView_GetItemState

Возвращает состояние пункта ListView

#include <GuiListView.au3>
_GUICtrlListView_GetItemState($hWnd, $iIndex, $iMask)

Параметры

$hWnd Дескриптор или идентификатор элемента
$iIndex Индекс пункта
$iMask Возвращаемая информация состояния. Это может быть комбинацией следующих значений:
    $LVIS_CUT - Пункт помечен для операции вырезать и вставить
    $LVIS_DROPHILITED - Пункт выделен как перетаскиваемый (drag-and-drop), чтобы бросить
    $LVIS_FOCUSED - Пункт находится в фокусе, это окружает его стандартным прямоугольником фокуса
    $LVIS_SELECTED - Пункт выделен
    $LVIS_OVERLAYMASK - Используйте эту маску для получения индекса накладываемого на пункт изображения
    $LVIS_STATEIMAGEMASK - Используйте эту маску для получения индекса статического изображения пункта

Возвращаемое значение

Возвращает текущее состояние указанного пункта

Примечания

Информация состояния пункта включает в себя набор флагов, а также индексы списка изображений, которые указывают статические и накладываемые изображения пунктов

См. также

_GUICtrlListView_SetItemState

Пример

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>

$Debug_LV = False ; Проверяет ClassName передаваемый в ListView функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hImage, $hListView

    GUICreate("ListView - Получает состояние пункта", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    _GUICtrlListView_SetExtendedListViewStyle($hListView, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_SUBITEMIMAGES))
    GUISetState()

    ; Загружает изображения
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x0000FF, 16, 16))
    _GUICtrlListView_SetImageList($hListView, $hImage, 1)

    ; Добавляет колонки
    _GUICtrlListView_AddColumn($hListView, "Колонка 1", 120)
    _GUICtrlListView_AddColumn($hListView, "Колонка 2", 120)
    _GUICtrlListView_AddColumn($hListView, "Колонка 3", 120)

    ; Добавляет пункты
    _GUICtrlListView_AddItem($hListView, "Стр 1: Кол 1", 0)
    _GUICtrlListView_AddSubItem($hListView, 0, "Стр 1: Кол 2", 1, 1)
    _GUICtrlListView_AddSubItem($hListView, 0, "Стр 1: Кол 3", 2, 2)
    _GUICtrlListView_AddItem($hListView, "Стр 2: Кол 1", 1)
    _GUICtrlListView_AddSubItem($hListView, 1, "Стр 2: Кол 2", 1, 2)
    _GUICtrlListView_AddItem($hListView, "Стр 3: Кол 1", 2)

    ; Устанавливает / получает состояние 1-го пункта
    _GUICtrlListView_SetItemState($hListView, 0, $LVIS_FOCUSED, $LVIS_FOCUSED) ; фокус
    MsgBox(4160, "Информация", "Состояние 1-го пункта: " & _GUICtrlListView_GetItemState($hListView, 0, $LVIS_FOCUSED))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main