_GUICtrlListView_GetItemImage
Возвращает индекс изображения указанного пункта
#include <GuiListView.au3>
_GUICtrlListView_GetItemImage($hWnd, $iIndex [, $iSubItem = 0])
Параметры
| $hWnd | Дескриптор или идентификатор элемента |
| $iIndex |
Индекс пункта, отсчёт от 0 |
| $iSubItem |
[необязательный] Индекс подпункта, отсчёт от 1 |
Возвращаемое значение
| Успех: | Возвращает индекс изображения, отсчёт от 0 |
| Ошибка: | Возвращает -1 |
См. также
_GUICtrlListView_SetItemImageПример
#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>
$Debug_LV = False ; Проверяет ClassName передаваемый в ListView функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает
_Main()
Func _Main()
Local $hImage, $hListView, $exStyles = BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_SUBITEMIMAGES)
GUICreate("Получает изображение пункта", 400, 300)
$hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
_GUICtrlListView_SetExtendedListViewStyle($hListView, $exStyles)
GUISetState()
; Загружает изображения
$hImage = _GUIImageList_Create()
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0xFF0000, 16, 16))
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x00FF00, 16, 16))
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x0000FF, 16, 16))
_GUICtrlListView_SetImageList($hListView, $hImage, 1)
; Добавляет колонки
_GUICtrlListView_AddColumn($hListView, "Колонка 1", 120)
_GUICtrlListView_AddColumn($hListView, "Колонка 2", 120)
_GUICtrlListView_AddColumn($hListView, "Колонка 3", 120)
; Добавляет пункты
_GUICtrlListView_AddItem($hListView, "Стр 1: Кол 1", 0)
_GUICtrlListView_AddSubItem($hListView, 0, "Стр 1: Кол 2", 1, 1)
_GUICtrlListView_AddSubItem($hListView, 0, "Стр 1: Кол 3", 2, 2)
_GUICtrlListView_AddItem($hListView, "Стр 2: Кол 1", 1)
_GUICtrlListView_AddSubItem($hListView, 1, "Стр 2: Кол 2", 1, 2)
_GUICtrlListView_AddItem($hListView, "Стр 3: Кол 1", 2)
; Устанавливает изображение пункта 1, подпункта 1
_GUICtrlListView_SetItemImage($hListView, 1, 1, 1)
MsgBox(4160, "Информация", "Изображение 1-го пункта, 1-го подпункта: " & _GUICtrlListView_GetItemImage($hListView, 1, 1))
; Цикл выполняется, пока окно не будет закрыто
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>_Main