↑  ←  Описание функции

_GUICtrlListView_GetImageList

Возвращает дескриптор используемого списка изображений

#include <GuiListView.au3>
_GUICtrlListView_GetImageList($hWnd, $iImageList)

Параметры

$hWnd Дескриптор или идентификатор элемента
$iImageList Возвращаемый список изображений:
    0 - Список изображений с большими иконками
    1 - Список изображений с маленькими иконками
    2 - Список изображений с изображениями состояния

Возвращаемое значение

Успех:Возвращает дескриптор указанного списка изображений
Ошибка:Возвращает 0

См. также

_GUICtrlListView_SetImageList

Пример

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>

$Debug_LV = False ; Проверяет ClassName передаваемый в ListView функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
    Local $hImage, $hListView

    GUICreate("Получает дескриптор списка изображений", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState()

    ; Загружает изображения
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x0000FF, 16, 16))
    _GUICtrlListView_SetImageList($hListView, $hImage, 1)

    ; Добавляет колонки
    _GUICtrlListView_AddColumn($hListView, "Колонка 1", 100)
    _GUICtrlListView_AddColumn($hListView, "Колонка 2", 100)
    _GUICtrlListView_AddColumn($hListView, "Колонка 3", 100)

    ; Добавляет пункты
    _GUICtrlListView_AddItem($hListView, "Пункт 1", 0)
    _GUICtrlListView_AddItem($hListView, "Пункт 2", 1)
    _GUICtrlListView_AddItem($hListView, "Пункт 3", 2)

    ; Получает дескриптор списка изображений
    $hImage2 = _GUICtrlListView_GetImageList($hListView, 1)
    MsgBox(4160, "Информация", "Дескриптор списка изображений: 0x" & Hex($hImage2) & @CRLF & _
        "он же, возвращённый функцией : 0x" & Hex($hImage) & @CRLF & _
        "IsPtr = " & IsPtr($hImage2) & @CRLF & _
        "IsHwnd = " & IsHWnd($hImage2))

    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main