↑  ←  Описание функции

_GUICtrlListView_EditLabel

Начать ручное редактирование текста указанного пункта

#include <GuiListView.au3>
_GUICtrlListView_EditLabel($hWnd, $iIndex)

Параметры

$hWnd Дескриптор или идентификатор элемента
$iIndex Индекс редактируемого пункта

Возвращаемое значение

Успех:Возвращает дескриптор элемента редактирования, который используется для редактирования пункта
Ошибка:Возвращает 0

Примечания

Когда пользователь завершает или отменяет редактирование, элемент редактирования уничтожается, и дескриптор больше не существует.
Вы можете унаследовать элемент редактирования, но вы не должны уничтожать его.

См. также

_GUICtrlListView_CancelEditLabel

Пример

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>
#include <WindowsConstants.au3>

$Debug_LV = False ; Проверяет ClassName передаваемый в ListView функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

Global $hListView, $iMemo

_Main()

Func _Main()
    Local $hGui, $hImage

    $hGui = GUICreate("ListView Редактируемое поле пункта", 400, 300)
    ; $hListView = GUICtrlCreateListView("", 2, 2, 394, 118, BitOR($LVS_EDITLABELS, $LVS_REPORT), $WS_EX_CLIENTEDGE)
    $hListView = _GUICtrlListView_Create($hGui, "", 2, 2, 394, 118, BitOR($LVS_EDITLABELS, $LVS_REPORT), $WS_EX_CLIENTEDGE)
    $iMemo = GUICtrlCreateEdit("", 2, 124, 396, 174, 0)
    GUISetState()

    ; Загружает изображения
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x0000FF, 16, 16))
    _GUICtrlListView_SetImageList($hListView, $hImage, 1)

    ; Добавляет колонки
    _GUICtrlListView_InsertColumn($hListView, 0, "Колонка 1", 120)
    _GUICtrlListView_InsertColumn($hListView, 1, "Колонка 2", 120)
    _GUICtrlListView_InsertColumn($hListView, 2, "Колонка 3", 120)

    ; Добавляет пункты
    _GUICtrlListView_AddItem($hListView, "Стр 1: Кол 1", 0)
    _GUICtrlListView_AddSubItem($hListView, 0, "Стр 1: Кол 2", 1)
    _GUICtrlListView_AddSubItem($hListView, 0, "Стр 1: Кол 3", 2)
    _GUICtrlListView_AddItem($hListView, "Стр 2: Кол 1", 1)
    _GUICtrlListView_AddSubItem($hListView, 1, "Стр 2: Кол 2", 1)
    _GUICtrlListView_AddItem($hListView, "Стр 3: Кол 1", 2)

    GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

    ; Редактируемое поле пункта с индексом 0, with time out
    Local $hEditLabel = _GUICtrlListView_EditLabel($hListView, 0)
    MemoWrite("Дескриптор редактируемого поля = 0x" & Hex($hEditLabel) & @CRLF & _
    "IsPtr = " & IsPtr($hEditLabel) & @CRLF & _
    "IsHWnd = " & IsHWnd($hEditLabel))


    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $iwParam
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndListView, $tInfo
    $hWndListView = $hListView
    If Not IsHWnd($hListView) Then $hWndListView = GUICtrlGetHandle($hListView)

    $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    Switch $hWndFrom
        Case $hWndListView
            Switch $iCode
                Case $LVN_BEGINLABELEDITA, $LVN_BEGINLABELEDITW ; Начало появления поля редактирования пункта
                    $tInfo = DllStructCreate($tagNMLVDISPINFO, $ilParam)
                    _DebugPrint("$LVN_BEGINLABELEDIT" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode & @LF & _
                            "-->Mask:" & @tab & DllStructGetData($tInfo, "Mask") & @LF & _
                            "-->Item:" & @tab & DllStructGetData($tInfo, "Item") & @LF & _
                            "-->SubItem:" & @tab & DllStructGetData($tInfo, "SubItem") & @LF & _
                            "-->State:" & @tab & DllStructGetData($tInfo, "State") & @LF & _
                            "-->StateMask:" & @tab & DllStructGetData($tInfo, "StateMask") & @LF & _
                            "-->Image:" & @tab & DllStructGetData($tInfo, "Image") & @LF & _
                            "-->Param:" & @tab & DllStructGetData($tInfo, "Param") & @LF & _
                            "-->Indent:" & @tab & DllStructGetData($tInfo, "Indent") & @LF & _
                            "-->GroupID:" & @tab & DllStructGetData($tInfo, "GroupID") & @LF & _
                            "-->Columns:" & @tab & DllStructGetData($tInfo, "Columns") & @LF & _
                            "-->pColumns:" & @tab & DllStructGetData($tInfo, "pColumns"))
                    Return False ; Позволяет пользователю редактировать поле
                    ;Return True  ; Предотвращает пользователю редактировать поле
                Case $LVN_COLUMNCLICK ; Клик на заголовке колонки
                    $tInfo = DllStructCreate($tagNMLISTVIEW, $ilParam)
                    _DebugPrint("$LVN_COLUMNCLICK" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode & @LF & _
                            "-->Item:" & @tab & DllStructGetData($tInfo, "Item") & @LF & _
                            "-->SubItem:" & @tab & DllStructGetData($tInfo, "SubItem") & @LF & _
                            "-->NewState:" & @tab & DllStructGetData($tInfo, "NewState") & @LF & _
                            "-->OldState:" & @tab & DllStructGetData($tInfo, "OldState") & @LF & _
                            "-->Changed:" & @tab & DllStructGetData($tInfo, "Changed") & @LF & _
                            "-->ActionX:" & @tab & DllStructGetData($tInfo, "ActionX") & @LF & _
                            "-->ActionY:" & @tab & DllStructGetData($tInfo, "ActionY") & @LF & _
                            "-->Param:" & @tab & DllStructGetData($tInfo, "Param"))
                    ; Нет возвращаемых значений
                Case $LVN_DELETEITEM ; Пункт собирается быть удален
                    $tInfo = DllStructCreate($tagNMLISTVIEW, $ilParam)
                    _DebugPrint("$LVN_DELETEITEM" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode & @LF & _
                            "-->Item:" & @tab & DllStructGetData($tInfo, "Item") & @LF & _
                            "-->SubItem:" & @tab & DllStructGetData($tInfo, "SubItem") & @LF & _
                            "-->NewState:" & @tab & DllStructGetData($tInfo, "NewState") & @LF & _
                            "-->OldState:" & @tab & DllStructGetData($tInfo, "OldState") & @LF & _
                            "-->Changed:" & @tab & DllStructGetData($tInfo, "Changed") & @LF & _
                            "-->ActionX:" & @tab & DllStructGetData($tInfo, "ActionX") & @LF & _
                            "-->ActionY:" & @tab & DllStructGetData($tInfo, "ActionY") & @LF & _
                            "-->Param:" & @tab & DllStructGetData($tInfo, "Param"))
                    ; Нет возвращаемых значений
                Case $LVN_ENDLABELEDITA, $LVN_ENDLABELEDITW ; Конец редактирования поля пункта
                    $tInfo = DllStructCreate($tagNMLVDISPINFO, $ilParam)
                    Local $tBuffer = DllStructCreate("char Text[" & DllStructGetData($tInfo, "TextMax") & "]", DllStructGetData($tInfo, "Text"))
                    _DebugPrint("$LVN_ENDLABELEDIT" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode & @LF & _
                            "-->Mask:" & @tab & DllStructGetData($tInfo, "Mask") & @LF & _
                            "-->Item:" & @tab & DllStructGetData($tInfo, "Item") & @LF & _
                            "-->SubItem:" & @tab & DllStructGetData($tInfo, "SubItem") & @LF & _
                            "-->State:" & @tab & DllStructGetData($tInfo, "State") & @LF & _
                            "-->StateMask:" & @tab & DllStructGetData($tInfo, "StateMask") & @LF & _
                            "-->Text:" & @tab & DllStructGetData($tBuffer, "Text") & @LF & _
                            "-->TextMax:" & @tab & DllStructGetData($tInfo, "TextMax") & @LF & _
                            "-->Image:" & @tab & DllStructGetData($tInfo, "Image") & @LF & _
                            "-->Param:" & @tab & DllStructGetData($tInfo, "Param") & @LF & _
                            "-->Indent:" & @tab & DllStructGetData($tInfo, "Indent") & @LF & _
                            "-->GroupID:" & @tab & DllStructGetData($tInfo, "GroupID") & @LF & _
                            "-->Columns:" & @tab & DllStructGetData($tInfo, "Columns") & @LF & _
                            "-->pColumns:" & @tab & DllStructGetData($tInfo, "pColumns"))
                    ; Если текст в поле имеется, то нужно возвратить True, чтобы применить изменения, если возвратить False, то действие редактирования отменяется
                    If StringLen(DllStructGetData($tBuffer, "Text")) Then Return True ; Если текст имеется, то применить
                Case $NM_CLICK ; Высылается элементом ListView, когда пользователь кликает пункт левой кнопкой мыши
                    $tInfo = DllStructCreate($tagNMITEMACTIVATE, $ilParam)
                    _DebugPrint("$NM_CLICK" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode & @LF & _
                            "-->Index:" & @tab & DllStructGetData($tInfo, "Index") & @LF & _
                            "-->SubItem:" & @tab & DllStructGetData($tInfo, "SubItem") & @LF & _
                            "-->NewState:" & @tab & DllStructGetData($tInfo, "NewState") & @LF & _
                            "-->OldState:" & @tab & DllStructGetData($tInfo, "OldState") & @LF & _
                            "-->Changed:" & @tab & DllStructGetData($tInfo, "Changed") & @LF & _
                            "-->ActionX:" & @tab & DllStructGetData($tInfo, "ActionX") & @LF & _
                            "-->ActionY:" & @tab & DllStructGetData($tInfo, "ActionY") & @LF & _
                            "-->lParam:" & @tab & DllStructGetData($tInfo, "lParam") & @LF & _
                            "-->KeyFlags:" & @tab & DllStructGetData($tInfo, "KeyFlags"))
                    ; Нет возвращаемых значений
                Case $NM_DBLCLK ; Высылается элементом ListView, когда пользователь делает двойной клик на пункте левой кнопкой мыши
                    $tInfo = DllStructCreate($tagNMITEMACTIVATE, $ilParam)
                    _DebugPrint("$NM_DBLCLK" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode & @LF & _
                            "-->Index:" & @tab & DllStructGetData($tInfo, "Index") & @LF & _
                            "-->SubItem:" & @tab & DllStructGetData($tInfo, "SubItem") & @LF & _
                            "-->NewState:" & @tab & DllStructGetData($tInfo, "NewState") & @LF & _
                            "-->OldState:" & @tab & DllStructGetData($tInfo, "OldState") & @LF & _
                            "-->Changed:" & @tab & DllStructGetData($tInfo, "Changed") & @LF & _
                            "-->ActionX:" & @tab & DllStructGetData($tInfo, "ActionX") & @LF & _
                            "-->ActionY:" & @tab & DllStructGetData($tInfo, "ActionY") & @LF & _
                            "-->lParam:" & @tab & DllStructGetData($tInfo, "lParam") & @LF & _
                            "-->KeyFlags:" & @tab & DllStructGetData($tInfo, "KeyFlags"))
                    ; Нет возвращаемых значений
                Case $NM_KILLFOCUS ; Элемент потерял фокус ввода
                    _DebugPrint("$NM_KILLFOCUS" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
                    ; Нет возвращаемых значений
                Case $NM_RCLICK ; Высылается элементом ListView, когда пользователь кликает пункт правой кнопкой мыши
                    $tInfo = DllStructCreate($tagNMITEMACTIVATE, $ilParam)
                    _DebugPrint("$NM_RCLICK" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode & @LF & _
                            "-->Index:" & @tab & DllStructGetData($tInfo, "Index") & @LF & _
                            "-->SubItem:" & @tab & DllStructGetData($tInfo, "SubItem") & @LF & _
                            "-->NewState:" & @tab & DllStructGetData($tInfo, "NewState") & @LF & _
                            "-->OldState:" & @tab & DllStructGetData($tInfo, "OldState") & @LF & _
                            "-->Changed:" & @tab & DllStructGetData($tInfo, "Changed") & @LF & _
                            "-->ActionX:" & @tab & DllStructGetData($tInfo, "ActionX") & @LF & _
                            "-->ActionY:" & @tab & DllStructGetData($tInfo, "ActionY") & @LF & _
                            "-->lParam:" & @tab & DllStructGetData($tInfo, "lParam") & @LF & _
                            "-->KeyFlags:" & @tab & DllStructGetData($tInfo, "KeyFlags"))
                    ;Return 1 ; не разрешает обработку по умолчанию
                    Return 0 ; разрешает обработку по умолчанию
                Case $NM_RDBLCLK ; Высылается элементом ListView, когда пользователь делает двойной клик на пункте правой кнопкой мыши
                    $tInfo = DllStructCreate($tagNMITEMACTIVATE, $ilParam)
                    _DebugPrint("$NM_RDBLCLK" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode & @LF & _
                            "-->Index:" & @tab & DllStructGetData($tInfo, "Index") & @LF & _
                            "-->SubItem:" & @tab & DllStructGetData($tInfo, "SubItem") & @LF & _
                            "-->NewState:" & @tab & DllStructGetData($tInfo, "NewState") & @LF & _
                            "-->OldState:" & @tab & DllStructGetData($tInfo, "OldState") & @LF & _
                            "-->Changed:" & @tab & DllStructGetData($tInfo, "Changed") & @LF & _
                            "-->ActionX:" & @tab & DllStructGetData($tInfo, "ActionX") & @LF & _
                            "-->ActionY:" & @tab & DllStructGetData($tInfo, "ActionY") & @LF & _
                            "-->lParam:" & @tab & DllStructGetData($tInfo, "lParam") & @LF & _
                            "-->KeyFlags:" & @tab & DllStructGetData($tInfo, "KeyFlags"))
                    ; Нет возвращаемых значений
                Case $NM_RETURN ; Элемент имеет фокус ввода и пользователь нажал клавишу ENTER
                    _DebugPrint("$NM_RETURN" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
                    ; Нет возвращаемых значений
                Case $NM_SETFOCUS ; Элемент получил фокус ввода
                    _DebugPrint("$NM_SETFOCUS" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
                    ; Нет возвращаемых значений
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

Func _DebugPrint($s_text, $line = @ScriptLineNumber)
    ConsoleWrite( _
            "!===========================================================" & @LF & _
            "+======================================================" & @LF & _
            "-->Строка(" & StringFormat("%04d", $line) & "):" & @TAB & $s_text & @LF & _
            "+======================================================" & @LF)
EndFunc   ;==>_DebugPrint

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite