_GUICtrlListView_DrawDragImage
Рисует перетаскиваемое изображение
#include <GuiListView.au3>
_GUICtrlListView_DrawDragImage(ByRef $hWnd, ByRef $aDrag)
Параметры
| $hWnd | Дескриптор элемента |
| $aDrag |
Массив следующего формата: [0] - Дескриптор перетаскиваемого списка изображений [1] - X-координата верхнего левого угла изображения [2] - Y-координата верхнего левого угла изображения |
См. также
_GUICtrlListView_CreateDragImageПример
#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>
$Debug_LV = False ; Проверяет ClassName передаваемый в ListView функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает
Example_UDF_Created()
Func Example_UDF_Created()
Local $GUI, $hImage, $aDrag, $hListView
$GUI = GUICreate("Рисует перетаскиваемое изображение (UDF)", 400, 300)
$hListView = _GUICtrlListView_Create($GUI, "", 2, 2, 394, 268)
GUISetState()
; Загружает изображения
$hImage = _GUIImageList_Create()
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0xFF0000, 16, 16))
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x00FF00, 16, 16))
_GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x0000FF, 16, 16))
_GUICtrlListView_SetImageList($hListView, $hImage, 1)
; Добавляет колонки
_GUICtrlListView_InsertColumn($hListView, 0, "Колонка 1", 100)
_GUICtrlListView_InsertColumn($hListView, 1, "Колонка 2", 100)
_GUICtrlListView_InsertColumn($hListView, 2, "Колонка 3", 100)
; Добавляет пункты
_GUICtrlListView_AddItem($hListView, "Красный", 0)
_GUICtrlListView_AddItem($hListView, "Зелёный", 1)
_GUICtrlListView_AddItem($hListView, "Синий", 2)
; Создаёт перетаскиваемое изображение
$aDrag = _GUICtrlListView_CreateDragImage($hListView, 0)
_GUICtrlListView_DrawDragImage($hListView, $aDrag)
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_MOUSEMOVE
_GUICtrlListView_DrawDragImage($hListView, $aDrag)
Case $GUI_EVENT_CLOSE
ExitLoop
EndSwitch
WEnd
; Удаляет список изображений
_GUIImageList_Destroy($aDrag[0])
GUIDelete()
EndFunc ;==>Example_UDF_Created